topic Re: How to set first observation as a Variables in SAS in SAS Programming

How to set first observation as a Variables in SAS

sas_lak — Wed, 03 Dec 2014 11:48:13 GMT

Hi All,

I need to drop variables and set First observation as a variables.

Ex:-

VARIABLES : - VAR1 VAR2 VAR3

OBSERVATION : - NAME1 NAME2 NAME3

XXXXX YYYYY ZZZZZ

AAAAA BBBBB CCCCC

OUTPUT LIKE : - NAME1 NAME2 NAME3

XXXXX YYYYY ZZZZZ

AAAAA BBBBB CCCCC

Thanks in advance .........!

Re: How to set first observation as a Variables in SAS

Loko — Wed, 03 Dec 2014 12:31:00 GMT

Hello,

One solution:

data have;
input (VAR1 VAR2 VAR3 ) ($);
datalines;
NAME1 NAME2 NAME3
XXXXX YYYYY ZZZZZ
AAAAA BBBBB CCCCC
;

data _null_;
set have (obs=1);
array charall{*} _character_;
length x $ 80;

do i=1 to dim(charall);
x=cat(strip(x),'rename ',vname(charall{i}),'=',strip(charall{i}),';');
end;
call symput('newvar',x);
run;

data want;
&newvar;
set have(firstobs=2);
run;

Re: How to set first observation as a Variables in SAS

RW9 — Wed, 03 Dec 2014 12:52:13 GMT

How are you arriving at your input dataset as it appears like an import data where getnames=no. I would suggest you address this in your actual import code. I would recommend not using proc import to start with. Write a datastep and do the work yourself, gives far more control. The way you are doing it may lead to problems, for instance do you check to see if the data is a valid SAS name?

Re: How to set first observation as a Variables in SAS

sbb — Wed, 03 Dec 2014 13:40:15 GMT

Consider investigating the merits with using PROC TRANSPOSE as well as DATA step processing to isolate in a separate SAS dataset/member those observations meaningful to your objective (resulting output dataset variable/column subset).

Scott Barry

SBBWorks, Inc.

Re: How to set first observation as a Variables in SAS

data_null__ — Wed, 03 Dec 2014 20:22:28 GMT

data have;
   input (var1-var3) ($);
   cards; 
NAME1  NAME2  NAME3
XXXXX  YYYYY  ZZZZZ
AAAAA  BBBBB  CCCCC
;;;;
   run; 
proc transpose data=have out=trans1;
   var var:;
   run; 
proc print; 
   run; 
proc transpose data=trans1 out=trans2(drop=_name_);
   id col1;
   var col2 col3;
   run; 
proc print; 
   run;