topic Re: need help in SAS Programming

need help reading multiple values on one line in DATA step

Sagar_Pawar — Thu, 28 Mar 2024 10:06:33 GMT

data a;
input id name: $30.;
datalines;
1 sachin,ramesh,tendulkar
2 narendra,modi
3 modi

output wants:
id name
1 sachin
1 ramesh
1 tendulkar
2 narendra
2 modi
3 modi

Re: need help

Patrick — Thu, 28 Mar 2024 09:05:47 GMT

data have;
  input id name: $30.;
  datalines;
1 sachin,ramesh,tendulkar
2 narendra,modi
3 modi
;

data want;
  set have;
  length name2 $10;
  drop name;
  do i=1 to countc(name,',')+1;
    name2=scan(name,i,',');
    output;
  end;
run;

Re: need help reading multiple values on one line in DATA step

Tom — Thu, 28 Mar 2024 13:31:50 GMT

That is what the trailing @ is for in the INPUT statement.

data a;
  infile datalines dsd dlm=', ' truncover;
  input id @;
  do col=1 by 1 ;
    input name :$30. @;
    if name=' ' and col>1 then leave;
    output;
  end;
datalines;
1 sachin,ramesh,tendulkar
2 narendra,modi
3 modi
4
;

proc print;
run;

Result

Obs    id    col    name

 1      1     1     sachin
 2      1     2     ramesh
 3      1     3     tendulkar
 4      2     1     narendra
 5      2     2     modi
 6      3     1     modi
 7      4     1

Re: need help

Sagar_Pawar — Thu, 28 Mar 2024 15:09:18 GMT

Thank you !!

Re: need help reading multiple values on one line in DATA step

Ksharp — Fri, 29 Mar 2024 02:22:48 GMT

data a;
infile cards dlm=' ,' truncover;
input id name :$80. @;
do while(not missing(name));
 output;
 input name :$80. @;
end;
datalines;
1 sachin,ramesh,tendulkar
2 narendra,modi
3 modi
;