topic Re: SQL Into by groups in SAS Programming

SQL Into by groups

david27 — Thu, 21 Mar 2024 16:03:20 GMT

This is what I have-- have.sas7bdat

I want to create a list of macro variables in a way that when I invoke

want_1_3 i get MDX

want_2_2 i get A4 3.0 4dr

How should I proceed?

proc sort data=sashelp.cars nodupkey out=cars(keep=make model);
	by make model;
run;

data have;
	set cars;
	by make model;
	retain id_groups 0;
	if first.make then
		do;
			id_groups+1;
			id_value_groups=1;
		end;
	else
		do;
			id_value_groups+1;
		end;
run;

Re: SQL Into by groups

ballardw — Thu, 21 Mar 2024 16:23:00 GMT

This?

data have;
	set cars;
	by make model;
	retain id_groups 0;
	if first.make then
		do;
			id_groups+1;
			id_value_groups=1;
		end;
	else
		do;
			id_value_groups+1;
		end;

   call symputx(catx('_','Make',id_groups,Id_value_groups),Model);
run;

%put &make_1_3;
%put &make_2_2;

If the only purpose of the data step is to create the macro variables then use a DATA _NULL_ as you don't need the data set.

Where does SQL come into this? SQL doesn't use BY groups per se.

Re: SQL Into by groups

david27 — Thu, 21 Mar 2024 17:08:15 GMT

True. I dont know why I was thinking this can be done only by SQL. Thank You very much @ballardw