topic Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar in SAS Programming

In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

DrAbhijeetSafai — Fri, 01 Mar 2024 09:29:33 GMT

Dear All,

Greetings!

I would like to know how to display percent on top of each bar and counts inside each bar in a graph. Answer with the specific option for the same will be really helpful. Thanks in advance!

Thanking you,

Yours sincerely,

- Dr. Abhijeet Safai

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

yabwon — Fri, 01 Mar 2024 09:35:21 GMT

Do you mean something like this:

https://communities.sas.com/t5/SAS-Visual-Analytics/Representation-of-a-histogram-stacked-at-100/m-p/873814#M17175

Bart

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

DrAbhijeetSafai — Fri, 01 Mar 2024 09:42:37 GMT

Yes @yabwon , the way in which the percent are appearing inside the bar, that is correct. However, the counts should be inside the bar, immediately below the top line of the bar and percent should be at the top of the bar.

Thank you.

- Dr. Abhijeet Safai

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

Ksharp — Fri, 01 Mar 2024 09:46:32 GMT

/*柱形图-分类变量*/
title  c=black  '按地区 分性别的柱形图';  
proc sort data=sashelp.heart out=temp;by bp_status;run;
proc freq data=temp noprint order=freq;
by bp_status;     
table status/out=temp2;  
run;
data temp3;
 set temp2;
 length _datalabel $ 40;
 _datalabel=cats(put(percent,8.2),'%/',count);
run;
proc sgplot data=temp3  ;
/*styleattrs datacolors=(grayaa lightblue lightred );*/
vbarparm category=bp_status response=count/ group=status  groupdisplay=cluster  
nooutline datalabel=_datalabel splitchar='/' datalabelpos=data ;
xaxis display=(nolabel);
keylegend /autooutline ;
run;

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

yabwon — Fri, 01 Mar 2024 09:46:44 GMT

For something like this the annotations data set will be required, give me a minute will try to prepare something.

Do you have any ""test data"?

Bart

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

DrAbhijeetSafai — Fri, 01 Mar 2024 09:59:38 GMT

Thanks @yabwon and @Ksharp for the response. Something like this is expected. Only the difference is that - the counts inside need not be associated with some other bar (which are associated with the pink bar inside the blue bar as shown in this image) but the counts should be immediately below the bar (inside) and the percent should be immediately above the individual bar (outside). Thanks a lot.

Thank you.

- Dr. Abhijeet Safai

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

yabwon — Fri, 01 Mar 2024 10:54:20 GMT

proc sort data=sashelp.heart out=temp;
  by bp_status status;
run;

proc freq data=temp noprint order=data;
  by bp_status;       
  table status/out=temp2 outcum;  
run;

proc sort data=temp2;
  by bp_status status;
run;

data annotation;
  set temp2;
  by bp_status;

  lag_percent=LAG(cum_pct);

  function="text";
  drawspace="datavalue";
  justify="center";
  textsize=10;
  justify= "center";
  width=100;
  widthunit="percent";

  XC1=bp_status;

  if first.bp_status then lag_percent=0;
  
  label=put(count,9.-L);
  anchor="bottom";
  y1=lag_percent+1;
  output;

  label=strip(put(percent,8.2) !! '%');
  anchor="top";
  y1=cum_pct-1;
  output;
run; 

proc sgplot data=temp2 sganno=annotation ;
  vbar bp_status / 
  group=status 
  response=percent 
  grouporder=data 
  ;
run;

Bart

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

yabwon — Fri, 01 Mar 2024 11:09:07 GMT

data have;
  call streaminit(123);
  do cat = "A","B","C";
    val1=rand('uniform',0,10);
    p=rand('uniform',0.2,0.5);
    val2=(1-p)*val1;
    output;
  end;
run;


proc sgplot data=have;
vbarparm category=cat response=val1 /
nooutline datalabel=val1 datalabelpos=data ;

vbarparm category=cat response=val2 /
nooutline datalabel=val2 datalabelpos=data 
BARWIDTH=0.5
;
run;

Bart

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

DrAbhijeetSafai — Fri, 01 Mar 2024 12:39:00 GMT

Thanks a lot.
It think this is the solution I was looking for. I will mark this as a solution soon. Thanks once again.

- Dr. Abhijeet Safai

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

Ksharp — Sun, 03 Mar 2024 08:02:39 GMT

proc sgplot data=sashelp.heart;
vbar bp_status/stat=freq datalabel legendlabel='Freq' ;
vbar bp_status/stat=percent datalabel y2axis barwidth=0.6 legendlabel='Percent';
yaxis  valueattrs=graphdata1 labelattrs=graphdata1;
y2axis values=(0 to 1 by 0.2) valueattrs=graphdata2 labelattrs=graphdata2;
run;

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

Ksharp — Sun, 03 Mar 2024 08:54:53 GMT

proc sort data=sashelp.heart out=temp;by bp_status;run;
proc freq data=temp noprint order=freq;
/*by bp_status;     */
table bp_status/out=temp2;  
run;
data temp3;
 set temp2;
 length _datalabel $ 40;
 _datalabel=cats(count,'/',put(percent,8.2),'%');
run;
proc sgplot data=temp3  noautolegend;
vbarparm category=bp_status response=count /nooutline;
text x=bp_status y=count text=_datalabel/splitchar='/' SPLITPOLICY=splitalways  strip contributeoffsets=none;
xaxis display=(nolabel);
yaxis offsetmax=0.1;
run;

Re: In proc sgplot, how to make percentages appear at the top of each bar and counts inside each bar

DrAbhijeetSafai — Mon, 04 Mar 2024 05:06:18 GMT

@Ksharp , Correct! Thanks a lot!

Thank you.

- Dr. Abhijeet Safai