topic Re: Nested loop not working with symput macro variables in SAS Programming

Nested loop not working with symput macro variables

bzimmermann — Thu, 29 Feb 2024 18:15:58 GMT

Hello All,

I am having an issue with this bit of code. I have created a null dataset containing the variables required in the loop macro and it also counts the number of observations. I want to run through each of the lines in the control_var dataset through the loop macro. But when I run the code it runs only the last row in the control_var table, it doesn't start at the first row. If I remove the macro and have the do statement run using a title i variable in the log it works starting at 1 and going through the 19 observations. So I believe the %do clause is accurate. There is something wrong with calling the variables from the control_var table

Any help you can give me would be greatly appreciated-thanks

%MACRO run_loops();

data _null_;

set control_var;

call symput ("year_qtr", year_qtr);

call symput ("qtr", qtr);

call symput ("nobs",_n_);

run;

%DO i = 1 %TO &nobs;

%loop(qtr=&&qtr&i,year_qtr=&&year_qtr&i);

%END;

%MEND run_loops;

%run_loops();

Re: Nested loop not working with symput macro variables

PaigeMiller — Thu, 29 Feb 2024 19:04:11 GMT

@bzimmermann wrote:

Hello All,

I am having an issue with this bit of code. I have created a null dataset containing the variables required in the loop macro and it also counts the number of observations. I want to run through each of the lines in the control_var dataset through the loop macro. But when I run the code it runs only the last row in the control_var table, it doesn't start at the first row.

Yes, that is how the data step works. For the first observation in data set CONTROL_VAR, it assigns &year_qtr the proper value based upon the first observation, and then on the second observation of data set CONTROL_VAR, it overwrites the value of &year_qtr to be correct for the second observation. And so on, until you get to the last observation of CONTROL_VAR, and it overwrites the value &year_qtr with the value on the last observation. So then your DO loop only has that available, it doesn't have the value of the other observations available.

You might want to consider CALL EXECUTE as a way of calling a macro with parameters based upon the data set value on each record. That link has an example of calling a macro based upon the values of a data set variable on each record. Another option is to put the DATA _NULL_ into the loop, and execute it to get the macro variables for just one observation (the &i-th observation).

Depending on what %LOOP is doing (we don't know, you didn't show us the code), you might be able to simplify the whole thing to use a BY statement and get rid of the macros entirely.

Re: Nested loop not working with symput macro variables

Tom — Thu, 29 Feb 2024 19:21:37 GMT

I don't see where you made any attempt to create a macro variable named QTR1 or QTR2.

Do you see that anywhere?

data _null_;
set control_var;
call symputX(cats("year_qtr",_n_), year_qtr);
call symputX(cats("qtr",_n_), qtr);
call symputX("nobs",_n_);
run;

PS Do not use the ancient CALL SYMPUT() function unless there is a reason why you need to store leading and/or trailing spaces into the macro variable.

Re: Nested loop not working with symput macro variables

Tom — Thu, 29 Feb 2024 19:29:52 GMT

Why bother making the macro variables at all?

Why not just generate the calls to %LOOP directly with SAS code?

For example by writing a program file and using %INCLUDE to run it.

Then you take advantage of the features of the PUT statement to make creating the code easier.

filename code temp;
data _null_;
  set control_var ;
  file code;
  put '%loop(' qtr= ',' year_qtr= ')' ;
run;
%include code / source2;

Re: Nested loop not working with symput macro variables

bzimmermann — Thu, 29 Feb 2024 20:25:31 GMT

Thank you all for your suggestions, I was able to use Paige's suggestion successfully.

data _null_;
set control_var;
call execute('%loop(qtr='||strip(qtr)||' ,year_qtr='||strip(year_qtr)||');');
run;

Re: Nested loop not working with symput macro variables

Quentin — Thu, 29 Feb 2024 22:30:42 GMT

Glad you got it working. Please mark Paige's answer as correct / accepted, to close out this question.