topic Re: how to mark the average value on the boxplot in SAS Programming

how to mark the average value on the boxplot

daun_14 — Mon, 26 Feb 2024 07:16:30 GMT

Hi, I want to know how to mark the average value on the boxplot.

Here is the phrase I wrote. How can I change it?

Proc sgplot data = A ;

Vbox scr1 / categorty=cd

group= cd boxwidth=0.8

capshape=none meanattrs=(symbol=diamond size=12);

axis color=black width=20;

run;

Thanks for appreciate!

Re: how to mark the average value on the boxplot

Ksharp — Mon, 26 Feb 2024 07:56:04 GMT

data have;
 set sashelp.heart;
 keep status bp_status  weight;
run;




proc summary data=have nway;
class status bp_status; 
var weight;    
output out=temp mean=mean;
run;
data want;
 set have temp;
run;
proc sgplot data=want noautolegend ;
Vbox weight / category=status group=bp_status boxwidth=0.8 
  capshape=none meanattrs=(symbol=diamond size=12);
scatter x=status y=mean /group=bp_status groupdisplay=cluster clusterwidth=0.7
   datalabel=mean datalabelattrs=(color=black) markerattrs=(size=0)  ;
xaxis display=(nolabel) ;
run;