topic Recognize pattern in SAS Programming

Recognize pattern

Ronein — Sun, 18 Feb 2024 08:39:05 GMT

Hello

I have a data set with char field that contain 6 figures 1/0.

I want to identify the following pattern (If this pattern then Indicator=1 else 0).

Block A- block of '1's in the right side

In the right side there will be continuous of one or several '1's and last number must be 1

Block B- block of '0's in the left side of block A

There can be one zero or multiple zeros in consecutive

Block C- block of '1's in the left side of block A

There can be one '1' or multiple '1's in consecutive

examples:

010101 -This pattern meet the criteria because Block A-1 Block B-0 Block C-1

000001--This pattern doesn't meet the criteria

000011--This pattern doesn't meet the criteria

101101-This pattern meet the criteria because Block A-1 Block B-0 Block C-11

101001-This pattern meet the criteria because Block A-1 Block B-00 Block C-1

010011-This pattern meet the criteria because Block A-11 Block B-00 Block C-1

What is the way to recognize this pattern?

Re: Recognize pattern

Ksharp — Sun, 18 Feb 2024 09:27:27 GMT

Data have;
input X $;
cards;
010101 
000001
000011
000111
001111
011111
111111
110011
110111
111001
100001
001001
001011
010011
101001
101101
;
Run;
data want;
 set have;
 y=prxchange('s/0+/0/',-1,x);
 z=prxchange('s/1+/1/',-1,y);
 Indicator=ifn(find(z,'101'),1,0);
 drop y z;
 run;

Re: Recognize pattern

Amir — Sun, 18 Feb 2024 09:48:41 GMT

Hi,

Thanks for supplying the input data in a data step. Please supply the expected output data in a data step too.

Please also clarify the following if the examples "000001" & "000011" don't meet the criteria because they do not satisfy Block C or is it something else?

Thanks & kind regards,

Amir.

Re: Recognize pattern

Ronein — Sun, 18 Feb 2024 09:49:42 GMT

Thanks

May you please explain

y=prxchange('s/0+/0/',-1,x);

Re: Recognize pattern

Ksharp — Mon, 19 Feb 2024 01:00:11 GMT

It is changing any continuous 0s (next to each other) to a single 0.
E.X.
10001 ->101
001 -> 01

So does
z=prxchange('s/1+/1/',-1,y);
change 1s to 1 .

Re: Recognize pattern

Ronein — Mon, 19 Feb 2024 02:04:53 GMT

"000001"
"000011"
They don't meet the criteria of block C (block C doesn't exist for them)

Re: Recognize pattern

Ronein — Mon, 19 Feb 2024 02:03:43 GMT

What is the meaning of "-1" in the formula?

Re: Recognize pattern

Ksharp — Wed, 21 Feb 2024 01:40:46 GMT

That means replace 0s to a single 0 any times as possible,
If it was 1 that means replace only one time.
i.e.
00010001 ->010001

Re: Recognize pattern

Ksharp — Thu, 22 Feb 2024 07:39:54 GMT

/*
Sorry. 
I found a problem in my code.
if you want 010100 be NOT matched, try this one:
*/

Data have;
input X $;
cards;
010101
010100
;
Run;
data want;
 set have;
 y=prxchange('s/0+/0/',-1,x);
 z=prxchange('s/1+/1/',-1,y);
 Indicator=ifn(prxmatch('/101$/',strip(z)),1,0);
 drop y z;
 run;

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 08:26:02 GMT

You already have an answer but, just for fun, one more:

Data have;
input X $;
cards;
010101 
000001
000011
000111
001111
011111
111111
110011
110111
111001
100001
001001
001011
010011
101001
101101
101100
;
Run;

data want;
  set have;
    marker = 
        mod(X,2) /* not ends with 0 */               
        * 
        (countw(X,"0","B") > 1) /* has at least 2 sequences of 1s (counting from right) */
    ;
run;
proc print;
run;

{EDIT:}

Of course if zeros on right aren't a problem (e.g., 010110 should be marked) then it reduces just to:

marker = (countw(X,"0","B") > 1);

{EDIT 2:}

To avoid ugly "types conversion" note in the log, the MOD() can be replaced with CHAR() function:

    marker = 
        char(X,6) = "1" /* not ends with 0 */               
        * 
        (countw(X,"0","B") > 1) /* has at least 2 sequences of 1s (counting from right) */
    ;

Bart

Re: Recognize pattern

Ronein — Thu, 22 Feb 2024 09:06:50 GMT

The rule is that if there is 1( or multiple 1's) and then 0( or multiple 0) and then 1( or multiple 1's) then indicator=1 .
It means that there is "hole" of zero between one's. In real life it mean that customer was exist snd then disappeared and then exist again

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 10:27:37 GMT

ok, so it looks like my code does what you need.

Re: Recognize pattern

Ronein — Thu, 22 Feb 2024 11:29:03 GMT

Both codes provide same result which is perfect:)

Data have;
input X $ 20.;;
cards;
010101 
000001
000011
000111
001111
011111
111111
110011
110111
111001
100001
001001
001011
010011
101001
101101
000000000001
000000000101
000000000011
000001011111
100000000001
101010101011
;
Run;

data want1;
set have;
y=prxchange('s/0+/0/',-1,x);
z=prxchange('s/1+/1/',-1,y);
Indicator1=ifn(find(z,'101'),1,0);
drop y z;
run;

data want2;
set have;
Indicator2 =  mod(X,2) /* not ends with 0 */ * (countw(X,"0","B") > 1) /* has at least 2 sequences of 1s (counting from right) */;
run;

proc sql;
create table compare_results(Where=(Indicator1 ne Indicator2)) as
select a.*,b.Indicator2
from want1  as a
left join want2 as b
on a.X=b.X
;
quit;

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 11:16:53 GMT

You didn't read what I wrote in my answer about "if zeros at the end are not important"...

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 11:18:39 GMT

BTW. your data step with example cuts your data in half...

Should be:

input X $ 20.;

or something like that....

Bart

Re: Recognize pattern

Ronein — Thu, 22 Feb 2024 11:30:05 GMT

Actually cannot have zero at end because the check is for customers that exist today (value 1)

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 11:33:34 GMT

Zero at the RightEnd of the string or at the LeftEnd?

1010101

1010100

0101010

0101011

Bart

Re: Recognize pattern

yabwon — Thu, 22 Feb 2024 11:39:04 GMT

But remember if the length of X exceeds capabilities of:

mod(X,2)

results won't be the same,

to be clear you can replace MOD() with

char(length(X)) = "1"

to verify if the last character is 1

Bart

Re: Recognize pattern

Ronein — Thu, 22 Feb 2024 14:21:50 GMT

Zero cannot be at right end because right end reflect existing of customers this month and the query check only customers existing this month