topic Re: Taking a random sample using SURVEYSELECT that contains at least one record from each group in SAS Programming

Taking a random sample using SURVEYSELECT that contains at least one record from each group

ghartge — Wed, 07 Feb 2024 19:33:37 GMT

Greetings,

OK, so I have a dataset where each row has

-course

-faculty

-student

-Group_Name

There are five different groups for the Group_Name value.

Is it possible to use SURVEYSELECT to take a random sample where at least one record from each group is produced and keep my results to an overall N?

I have used PROC SURVEYSELECT to produce data where each group in represented using STRATA Group_Name;, but each group is also equal to my N. In other words, five groups of 31 in my output data (155 records) instead of a total of 31 records with each of the five groups represented at least once.

PROC SURVEYSELECT DATA = Data_In OUT = Data_Out
n=31
seed = 12345
method = srs;
STRATA Group_Name;
RUN ;

To restate my question, I would like to produce only 31 records in my Data_Out dataset, but have each "Group" represented at least once.

Commenting out the line "STRATA Group_Name;" line produces 31 records equaling my N value, and has up to now produced at least one record from each group, but is this how PROC SURVEYSELECT functions or have I simply been lucky?

Thanks,

Gary

Re: Taking a random sample using SURVEYSELECT that contains at least one record from each group

FreelanceReinh — Thu, 08 Feb 2024 13:06:51 GMT

Hello @ghartge,

I think adding the ALLOC=PROP option to the STRATA statement should solve the problem:

strata Group_Name / alloc=prop;

The documentation of the related ALLOCMIN= option (by which you could request at least n observations per stratum) says: "By default, PROC SURVEYSELECT allocates at least one sampling unit to each stratum." At the same time, proportional allocation comes close to what a simple random sample would yield on average.

Edit: If you want to allow variability in the frequency distribution of variable Group_Name in the result, you can perform the selection in two steps:

One randomly selected observation from each group.
A simple random sample of 31−5=26 observations from the remaining observations, without stratification.

Code:

proc surveyselect data=data_in
method=srs n=1 outall
seed=12345 out=step1;
strata Group_Name;
run;

proc surveyselect data=step1(where=(not selected))
method=srs n=26
seed=2718 out=step2;
run;

data want;
set step1(where=(selected))
    step2;
by Group_Name;
drop Selected SelectionProb SamplingWeight;
run;

Re: Taking a random sample using SURVEYSELECT that contains at least one record from each group

ghartge — Thu, 08 Feb 2024 13:13:21 GMT

Great @FreelanceReinh ! Thank you and thanks for the quick response.

Gary