topic Re: Storing and then executing a complete SAS steps/ progs as a macro variable? in SAS Programming

Storing and then executing a complete SAS steps/ progs as a macro variable?

Ram_SAS — Sat, 03 Feb 2024 18:01:19 GMT

Hi,

Wondering if we need to store a complete SAS steps/ procedure as a macro variable, how can we view those without any log issues and how can we execute those? Example see below, I am capturing a simple data step in VARLIST, eventually want to capture that as a macro variable (&step) and then execute the resolved macro variable? Thank you.

data test;
length varlist $1000;
varlist= " data x;length name $25; name='abc'; output; name='edfs'; output; run;";
run;
data _null_;
    set test end=eof;
    if eof then call symputx('step',varlist);
run;
%put %superq(&step);

Re: Storing and then executing a complete SAS steps/ progs as a macro variable?

Tom — Sat, 03 Feb 2024 18:06:12 GMT

Remove the & from your code. The %SUPERQ() function wants the NAME of a macro variable, not its value.

%put %superq(step);

Re: Storing and then executing a complete SAS steps/ progs as a macro variable?

Ram_SAS — Sat, 03 Feb 2024 18:12:18 GMT

Thanks looks like I had &step, when I was calling superq. How can I execute those?

Re: Storing and then executing a complete SAS steps/ progs as a macro variable?

Ram_SAS — Sat, 03 Feb 2024 18:23:13 GMT

I got it to work with Call execute as below, is there any other suggestions? Thank you.

data test;
length varlist $1000;
varlist= " data x;length name $25; name='abc'; output; name='edfs'; output; run;";
run;
data _null_;
    set test end=eof;
    if eof then call symputx('step',varlist);
	call execute('%NRSTR(' || "&step" || ')');
run;
%put %superq(step);

Re: Storing and then executing a complete SAS steps/ progs as a macro variable?

Tom — Sat, 03 Feb 2024 18:24:33 GMT

Just expand the macro variable between other steps in your program.

proc print data=sashelp.class;
run;

&step

proc print data=x;
run;

Re: Storing and then executing a complete SAS steps/ progs as a macro variable?

Tom — Sat, 03 Feb 2024 19:18:07 GMT

If the goal is just to run it immediately then there is no need to put it into a macro variable.

call execute(trim(varlist));

Or instead of macro variables you can put it into an actual FILE.

filename code temp;
data _null_;
  set test;
  file code;
  put varlist;
run;

And then use %INCLUDE to run it.

%include code / source2;

What do you want to do when you have more than one block of code to store?

For example perhaps you have a dataset that is something like this:

data test;
  step+1;
  length varlist $1000;
  varlist= " data x;length name $25; name='abc'; output; name='edfs'; output; run;";
  output;
  step+1;
  varlist='proc print data=x; run;';
  output;
run;

Now you can put it into multiple macro variables.

data _null_;
  set test;
  call symputx(cats('step',step),varlist);
run;

Which you can then run independently.

&step1
proc sort data=x; 
  by name;
run;
&step2

Or perhaps just run them using call execute;

data _null_;
  set test;
  call execute(catx(' ','* STEP',step,';'));
  call execute(trim(varlist));
run;