topic Re: How to convert YYYY-MM-DD char variable to date? in SAS Programming

How to convert YYYY-MM-DD char variable to date?

TMoseley1980 — Mon, 29 Jan 2024 23:31:05 GMT

I have a lot of date variables that came out of a database stored as text, in the format YYYY-MM-DD real example : 1998-01-15

. Found examples, and I've found a list of date formats, but none of them match this. The data starts in 1997, so all four year digits are important.

Thanks for your help.

Re: How to convert YYYY-MM-DD char variable to date?

PaigeMiller — Mon, 29 Jan 2024 23:52:13 GMT

data want;
    set have;
    date_var=input(char_var,yymmdd10.);
    format date_var yymmddd10.;
run;

Re: How to convert YYYY-MM-DD char variable to date?

ballardw — Tue, 30 Jan 2024 00:27:15 GMT

Some of the date informats (you don't want a format to read data) are pretty tolerant of characters as long as they are used consistently, as is same between year and month and day.

data example;
   input string :$10.;
   date_var = input(string,yymmdd10.);
   format date_var yymmddd10.;
datalines;
1998-01-15
1998/01/15
1998*01*15
1998!01!15
1998#01#15
1998\01\15
1998|01|15
1998$01$15
1998^01^15
1998(01(15
1998%01%15
1998&01&15
19980115
;

While I wouldn't expect to see some of those in most files you might be surprised some time.

Actually you concern about 4 digit years is well founded and should be thankful all four are provided. It is the idiots that dump something like 010203 with two digit years and you don't know if that is supposed to be 3 Feb 2001 (or 3 Feb 1901), 2 Mar 2001, 1 Feb 2003 or 2 Jan 2003.

Re: How to convert YYYY-MM-DD char variable to date?

SASKiwi — Tue, 30 Jan 2024 01:48:08 GMT

How are these date variables stored in the source database? If their column types are date or datetime at source it could be easier to fix the extract process rather than bandaid the data afterwards.