topic two reference lines in proc sqplot in SAS Programming

two reference lines in proc sqplot

jojo — Thu, 18 Jan 2024 23:02:55 GMT

I tried to use thee following code to add two reference lines in thee plot, why the label for second line doesn't show in the plot?

proc sgplot data=indata;

series x=visit y=result/group=usubjid datalabelattrs=(size=12pt) markers markerattrs=(size=12pt symbol=trianglefilled)

lineattrs=(thickness=3 pattern=solid) name="series_name";

keylegend "series_name" / valueattrs=(size=14);

refline 0 / axis=y lineattrs=(thickness=3 pattern=dash) label=("Upper Level of Healthy");

refline LLOQn / axis=y lineattrs=(thickness=3 pattern=dash) label=("LLOQ") labelloc=inside;

xaxis label="Visit" labelattrs=(size=16pt) VALUEATTRS=(Size=12

Weight=Bold);

yaxis label="sample data" labelattrs=(size=16pt) VALUEATTRS=( Size=12

Weight=Bold);

run;

Re: two reference lines in proc sqplot

ballardw — Thu, 18 Jan 2024 23:54:41 GMT

You may have to provide actual data to diagnose this. What does your LOG show when you run this code? Copy the text from the log window of the code and all the notes or other messages and paste the result into a text box opened on the forum with the </> icon that appears above the message window. The text box preserves diagnostic messages better than the main message window which will reformat pasted text and remove spaces and possibly replace characters.

Question: What is the value(s) for the variable LLOQN and the maximum and minimum of the variable Result?

Re: two reference lines in proc sqplot

Quentin — Fri, 19 Jan 2024 04:18:15 GMT

I ran this similar code:

proc sgplot data=sashelp.class;
  series x=height y=weight;
  refline 0 / axis=y lineattrs=(thickness=3 pattern=dash) label=("Upper Level of Healthy") noclip;
  refline age / axis=y lineattrs=(thickness=3 pattern=dash) label=("LLOQ") labelloc=inside noclip;
run;

And there is a NOTE in the log explaining why the label for the second refline statement is not created:

NOTE: CURVELABEL='LLOQ' is invalid. The option value cannot be a string when a column of reference lines is plotted. The label
      will not be drawn.

When you specify the refline as a variable, it suggests that you want to create mutiple reference lines, one for each value in the variable. It wouldn't make sense to apply one label, "LLOQ" to multiple reference lines. When you use refline variable, SGPLOT expects you to use label=variable, not label="text string".

So this code "works":

proc sgplot data=sashelp.class;
  series x=height y=weight;
  refline 0 / axis=y lineattrs=(thickness=3 pattern=dash) label=("Upper Level of Healthy") noclip;
  refline age / axis=y lineattrs=(thickness=3 pattern=dash) label=name labelloc=inside noclip;
run;

(The plot is nonsensical and the labels collide, but they are printed.)