topic Re: Check if current time less than a value in SAS Programming

Check if current time less than a value

hhchenfx — Tue, 02 Jan 2024 21:09:31 GMT

Hi,

I want to compare current time with '4:55't as below but my code is not working.

Can you please help to fix?

Thanks,

HHC

%MACRO _BREAK() ;
%let current_time = time(); /* Get the current time */

%IF &current_time < '4:55't %then %do;
	%put "print before ";
	%END;
%ELSE %do;
	%put "print after";
	%END;

%Mend;

%_BREAK();

Re: Check if current time less than a value

Kurt_Bremser — Tue, 02 Jan 2024 21:17:42 GMT

%let current_time = time(); /* Get the current time */

Here, you assign the text time() to the macro variable (not the result of the function!). If you want to execute a data step function in macro code, you need to use %SYSFUNC:

%let current_time = %sysfunc(time());

Re: Check if current time less than a value

SASKiwi — Tue, 02 Jan 2024 21:24:17 GMT

It's a lot easier not using macro logic - not sure why you need a macro at all:

%MACRO _BREAK() ;

data _null_;
  if time() < '4:55't then putlog "print before ";
  else putlog "print after";
run;

%Mend;

%_BREAK();

Re: Check if current time less than a value

LynnP_sas — Tue, 02 Jan 2024 21:32:31 GMT

Greetings,

I made the following modifications to your code:

%MACRO _BREAK() ;

%let current_time = %sysfunc(time()); /* Get the current time */

%put curr is &current_time;

%IF %sysevalf(&current_time < '20:55't) %then %do;

%put "print before ";

%END;

%ELSE %do;

%put "print after";

%END;

%Mend;

%_BREAK();

The problems you were having are due to the macro facility only understanding text.

Re: Check if current time less than a value

hhchenfx — Tue, 02 Jan 2024 22:47:11 GMT

Thank you so much for helping!

HHC