topic Re: A question about break after statement in the proc report in SAS Programming

A question about break after statement in the proc report

Sikcion — Mon, 01 Jan 2024 21:36:55 GMT

Hi guys! I have one question about "break after" statement:

I want to create a table like below:

and here is my code:

proc report data=table12 nowindows headline headskip spacing = 10 style(header)={nobreakspace=on};
columns AVISITN_1 Trt01a count mean_se;
define AVISITN_1/group order=data center width =20 " Test Day " style(column)={just=c};
define Trt01a /display center width=10 "Treatment" ;
define count / display center width =14 "N";
define mean_se /display center width = 40" Adjusted Mean(SE)";
title1 bold "Table11";
title2 bold "Summary od Blood Glucose Level over time";
title3 bold "ITT Subjects";

compute after AVISITN_1;
line " ";
endcomp;

compute after ;
line @3 %sysfunc(repeat(——, 55));
line @3 "Adjusted mean is calculated using PROC MIXED stage as factor and treatment.";
endcomp;
run;
ods pdf close;

and my output:

I found even though I add :

compute after ;
line @3 %sysfunc(repeat(——, 55));

there is no line above the "Adjusted mean is calculated using PROC MIXED stage as factor and treatment."

Thanks for your help!

Re: A question about break after statement in the proc report

Kurt_Bremser — Mon, 01 Jan 2024 21:47:00 GMT

Try

line @3 "%sysfunc(repeat(——, 55))";

Re: A question about break after statement in the proc report

Ksharp — Tue, 02 Jan 2024 04:33:41 GMT

data table12;
set sashelp.heart(obs=10);
run;

ods pdf file='c:\temp\temp.pdf';
proc report data=table12 nowindows headline headskip spacing = 10 style(header)={nobreakspace=on};
columns status weight ageatstart height;
define status/group order=data center width =20 " Test Day " style(column)={just=c};
define weight /display center width=10 "Treatment" ;
define ageatstart / display center width =14 "N";
define height /display center width = 40" Adjusted Mean(SE)";
title1 bold "Table11";
title2 bold "Summary od Blood Glucose Level over time";
title3 bold "ITT Subjects";

compute after status;
line " ";
endcomp;

compute after ; 
line @3 "(*ESC*){style [textdecoration=overline] Adjusted mean is calculated using PROC MIXED stage as factor and treatment.                }";
endcomp;
run;
ods pdf close;