topic Re: Trying read SAS program and store it in the DATASET. in SAS Programming

Trying read SAS program and store it in the DATASET.

u63406443 — Mon, 20 Nov 2023 11:11:08 GMT

Hi All,

I am trying reading the entire SAS program (.sas files) and storing entire program code in the dataset using option filename statement, but here problem is it is not able to fetch all lines of code instead fetching few lines. Can anyone please help me?

code:

filename rd 'C:\Users\rakes\Documents\My SAS Files\sas_practice\program_2.sas';

data temp;
infile rd;
input rec $150.;
run;

Thanks,

Rakesh.

Re: Trying read SAS program and store it in the DATASET.

Kurt_Bremser — Mon, 20 Nov 2023 11:35:50 GMT

Why do you want to do this? Programs are stored best in their text form.

The default value for an overflow while reading an external file is MISSOVER, so any line shorter than 150 characters will cause a missing value.

Change your code:

data temp;
infile "C:\Users\rakes\Documents\My SAS Files\sas_practice\program_2.sas" truncover;
input rec $150.;
run;

Since you seem to get some lines with your original code, you may have to increase the informat, and also set a proper LRECL= option in the INFILE statement.

Re: Trying read SAS program and store it in the DATASET.

Ksharp — Mon, 20 Nov 2023 11:37:31 GMT

filename rd 'C:\temp\a.sas';

data temp;
infile rd length=len;
input rec $varying200. len;
run;

Re: Trying read SAS program and store it in the DATASET.

u63406443 — Tue, 21 Nov 2023 05:18:28 GMT

Hi Kurt_Bremser,

I need below program, because I merging almost 60 SAS codes, and filtering with a condition. I truly appreciate the update; it's been quite useful.

Thank you Kurt_Bremser

Re: Trying read SAS program and store it in the DATASET.

u63406443 — Tue, 21 Nov 2023 05:19:04 GMT

Thank you Ksharp.

Re: Trying read SAS program and store it in the DATASET.

Patrick — Tue, 21 Nov 2023 06:53:43 GMT

If this is for some sort of impact analysis like to find all programs that use a certain table:

I used to use Atom for such tasks but this tool got unfortunately depreciated.

You could still use Notepad++ to search through all .sas programs under a folder or even folder and sub-folders

Or for files under Linux/Rhel a grep command is often fit for purpose - potentially in combination with a find command.

If you want to use SAS for such a search then you could use the infile statement with a wildcard which would allow to write code that reads all .sas files in a folder in one go.

Re: Trying read SAS program and store it in the DATASET.

yabwon — Tue, 21 Nov 2023 07:40:11 GMT

Yet another way, with getting the buffer:

filename rd 'C:\SAS_PACKAGES_DEV\SPFinit.sas';

data temp;
  infile rd;
  input;
  length rec $ 256;
  rec = _infile_;
run;

Bart

Re: Trying read SAS program and store it in the DATASET.

Tom — Tue, 21 Nov 2023 15:20:20 GMT

Because you used the default FLOWOVER setting for the INFILE statement when you tried to read past the end of a line SAS went to the next line to find the data.

Let's use an example using in-line data (requires informat longer than 80 since in-line data is padded to next multiple of 80 column card image).

data test;
  input line $100.;
cards4;
line one
line two
line three
line four
line five
;;;;

Result

You want to use the TRUNCOVER option.

You also want to use $CHAR informat to preserve any leading spaces on the lines.

data test;
  infile cards truncover;
  input line $char100.;
cards4;
filename rd 'C:\Users\rakes\Documents\My SAS Files\sas_practice\program_2.sas';

data temp;
  infile rd;
  input rec $150.;
run;

;;;;


proc print;
run;

Result

 Obs    line

 1     filename rd 'C:\Users\rakes\Documents\My SAS Files\sas_practice\program_2.sas';
 2
 3     data temp;
 4       infile rd;
 5       input rec $150.;
 6     run;
 7