topic Re: Identify dates that fall in last week of the month in SAS Programming

Identify dates that fall in last week of the month

PamG — Fri, 17 Nov 2023 17:37:14 GMT

How do I identify dates that fall in the last week of the month?

How do I identify dates that fall in the last week of the month?

DATA dates;
INPUT startdt :mmddyy10.;
FORMAT startdt mmddyy10.;
DATALINES;
12/01/2000
09/30/2012
06/01/2001
09/01/2001
09/30/2018
09/30/2018
04/30/2017
;
RUN;

Re: Identify dates that fall in last week of the month

PaigeMiller — Fri, 17 Nov 2023 17:51:26 GMT

Please let us know how you define "week". Does it start on Saturday, or Sunday, or Monday? Or do you mean last 7 days? Or do you mean something else?

Please be specific and detailed.

Re: Identify dates that fall in last week of the month

Astounding — Fri, 17 Nov 2023 18:08:29 GMT

If you mean the last 7 days of the month, here's a way:

data want;
   set have;
   if (intnx('month', startdt, 1) -7) <= startdt < intnx('month', startdt, 1);
run;

Re: Identify dates that fall in last week of the month

Reeza — Fri, 17 Nov 2023 18:12:51 GMT

Assuming last 7 days.

data want;
set dates;
in_last_7days = startdt >= intnx('month', startdt, 0, 'e') - 7;
run;

Re: Identify dates that fall in last week of the month

Ksharp — Sat, 18 Nov 2023 10:39:42 GMT


DATA dates;
INPUT startdt :mmddyy10.;
first=nwkdom(5,2,month(startdt),year(startdt));
in_last_week=(startdt>=first);
FORMAT first startdt mmddyy10.;
DATALINES;
12/01/2000
09/30/2012
06/01/2001
09/01/2001
09/30/2018
09/30/2018
04/30/2017
;
RUN;

Re: Identify dates that fall in last week of the month

PamG — Mon, 20 Nov 2023 15:31:16 GMT

Thanks you so much @Ksharp Ksharp. This is exactly what I was looking for. To be able to identify the start date of the last week of the month. I wasn't aware of the NWKDOM function. Than you for bringing it to our attention!!!