topic Re: finding maximum value in an array and averaging max-1, max and max+1 in SAS Programming

finding maximum value in an array and averaging max-1, max and max+1

mateescu — Thu, 09 Nov 2023 14:35:53 GMT

I have a dataset looking like this:

data test;

array var(10) var1-var10;

cards;

1 2 3 4 5 4 3 2 1 1

. . . . . . . . . . .

;

run;

I want to find the maximum value in the array (in this case 5) and average the 3 values around it (the max value, max-1 and max+1 - in the example 4,5 and 4)

Thanks!

Re: finding maximum value in an array and averaging max-1, max and max+1

PaigeMiller — Thu, 09 Nov 2023 14:58:15 GMT

data want;
    set test;
    array v var1-var10;
    maximum_value=max(of var1-var10);
    loc=whichn(maximum_value,of var1-var10);
    avg_of_3=mean(v(loc-1),v(loc),v(loc+1));
run;

Note: this code fails if the maximum of var1-var10 is in position 1 or position 10. If the maximum appears at two or more locations, it will find only the first such occurrence of the maximum and work with that.

Re: finding maximum value in an array and averaging max-1, max and max+1

mateescu — Thu, 09 Nov 2023 16:32:15 GMT

Thank you - works perfectly! Sorry about the code. Here is the complete code including yours:

data test;
input var1-var10;
cards;
1 2 3 4 5 4 3 2 1 1 
1 3 4 5 6 3 5 2 2 1
;
run;
data want;
    set test;
    array v var1-var10;
    maximum_value=max(of var1-var10);
    loc=whichn(maximum_value,of var1-var10);
    avg_of_3=mean(v(loc-1),v(loc),v(loc+1));
run;

Re: finding maximum value in an array and averaging max-1, max and max+1

Tom — Fri, 10 Nov 2023 03:13:20 GMT

You can fix the boundary condition by adding two extra variables (with missing values) to the ARRAY. You can use just one variable and add it twice to the array.

The result be the average of the TWO values at the boundary since the third value will be missing.

data want;
    set test;
    array v var0 var1-var10 var0;
    maximum_value=max(of v[*]);
    loc=whichn(maximum_value,of v[*]);
    avg_of_3=mean(v(loc-1),v(loc),v(loc+1));
    drop var0  ;
run;

Re: finding maximum value in an array and averaging max-1, max and max+1

PaigeMiller — Fri, 10 Nov 2023 10:49:52 GMT

@Tom wrote:

You can fix the boundary condition by adding two extra variables (with missing values) to the ARRAY. You can use just one variable and add it twice to the array.

The result be the average of the TWO values at the boundary since the third value will be missing.

True if that's what the OP wanted. However, no such statement from the OP has been made, so I didn't try to code anything for boundary conditions.

Re: finding maximum value in an array and averaging max-1, max and max+1

mateescu — Fri, 10 Nov 2023 12:20:23 GMT

I did something similar (see code below) but your solution is more elegant. Thanks! I know I didn't ask for this, but just because I didn't think of that problem in the beginning. I appreciate all the help.

data want;
    set test;
    array v var1-var10;
    maximum_value=max(of var1-var10);
    loc=whichn(maximum_value,of var1-var10);
    if loc ge 2 and loc le 9 then avg_of_3=mean(v(loc-1),v(loc),v(loc+1));
	if loc=1 then avg_of_3=mean(v(loc),v(loc+1));
	if loc=10 then avg_of_3=mean(v(loc),v(loc-1));
run;

Re: finding maximum value in an array and averaging max-1, max and max+1

PaigeMiller — Fri, 10 Nov 2023 12:21:40 GMT

Looks good to me! Good for you to make the fix by yourself.