topic Re: How to extend GTL heatmap area to full graph wall? in SAS Programming

How to extend GTL heatmap area to full graph wall?

whymath — Sat, 07 Oct 2023 02:23:41 GMT

I am working on a heatmap graph using GTL. The main part is finished, albeit a little imperfect. I want the 100% area of the graph wall is used for the heatmap, but there is always a gap between the outline of the graph wall and the heatmap.

Following is an example:

proc template;
  define statgraph heatmapparm;
    begingraph;
      layout overlay/xaxisopts=(linearopts=(viewmin=50 viewmax=80));
        heatmapparm x=height y=weight colorresponse=count /
          name="heatmapparm" xbinaxis=false ybinaxis=false;
        continuouslegend "heatmapparm" / location=outside valign=bottom;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=sashelp.gridded template=heatmapparm;
run;

As you can see, there are four gaps between the heatmap and the graph wall in four directions. I want to extend the heatmap to fullfill 100% area of the graph wall, is that possible? How to make it in GTL?

Re: How to extend GTL heatmap area to full graph wall?

Patrick — Sat, 07 Oct 2023 03:57:19 GMT

Just by trying: You could define the collor for the wallcolor the same as for the minimum value in the colormodel.

proc template;
  define statgraph heatmapparm;
    begingraph;
      layout overlay/xaxisopts=(linearopts=(viewmin=50 viewmax=80)) wallcolor=cx8097b2;
        heatmapparm x=height y=weight colorresponse=count /
          name="heatmapparm" xbinaxis=false ybinaxis=false
          colormodel=(cx8097b2 White cxd05b5b)
          ;
        continuouslegend "heatmapparm" / location=outside valign=bottom;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=sashelp.gridded template=heatmapparm;
run;

Re: How to extend GTL heatmap area to full graph wall?

FreelanceReinh — Sat, 07 Oct 2023 09:14:44 GMT

Hello @whymath,

With your sample data it helps to avoid specifying VIEWMIN/VIEWMAX values outside the data range and instead to set THRESHOLDMIN, THRESHOLDMAX, OFFSETMIN and OFFSETMAX to zero. The LINEEXTENT=DATA option seems to be redundant in this case, but could also be included.

layout overlay/xaxisopts=(linearopts=(thresholdmin=0 thresholdmax=0) offsetmin=0 offsetmax=0 /* lineextent=data */)
               yaxisopts=(linearopts=(thresholdmin=0 thresholdmax=0) offsetmin=0 offsetmax=0 /* lineextent=data */);