topic Re: SAS proc format consequence problem in SAS Programming

SAS proc format consequence problem

bbibbi_yc — Wed, 27 Sep 2023 08:25:56 GMT

Hi, this is my code about proc format and the outcome.

And I got a note:

NOTE: Format EDU is already on the library WORK.FORMATS.

NOTE: Format EDU has been output.

I am wondering where is my outcome about the proc format.

Thank u.

Re: SAS proc format consequence problem

Astounding — Wed, 27 Sep 2023 09:15:54 GMT

You copied some notes you received about the EDU format. Where did you find those notes?

Re: SAS proc format consequence problem

PaigeMiller — Wed, 27 Sep 2023 11:12:30 GMT

NOTE in the log does not indicate a problem. It is just providing information.

In PROC FREQ, you have to assign the format(s) to the variable(s). You have not done that. I'm sure that your class notes explain how to do that.

Side note: if you are going to assign a format, use proper proper capitalization, proper grammar and so on. For example

value mar 1='Single' ... ;

The reason you use formats is to make something more readable and more meaningful; if you want to make things more readable, use proper capitalization and grammar.

Re: SAS proc format consequence problem

bbibbi_yc — Wed, 27 Sep 2023 15:20:34 GMT

In the diary.

And now I use another ways but still not solve the problem.

Thank u.

Re: SAS proc format consequence problem

Reeza — Wed, 27 Sep 2023 15:25:05 GMT

Different problem.

$EDU and EDU are different formats.

$ indicates a character format.

Your formats should be EDU and MAR

format EDU edu. Mar mar.;

For simplicity, I recommend not using the same name for your format and variable, I usually add the _fmt at the end.

edu_fmt and mar_fmt are clearer.

I'd show you how that works but I'm not going to type out your code. Please post your code as text in the future.

Re: SAS proc format consequence problem

PaigeMiller — Wed, 27 Sep 2023 18:50:14 GMT

Your format MAR does not have a $ in the name. Same for EDU. In addition, there is no need to create a whole new data set to assign formats. The entire code you have written can be simplified

filename refile_1 '/home/...';
proc import datafile=refile_1 out=homework dbms=xlsx; 
getnames=yes;
run;
proc format;
    value edu 1='Illiteracy' 2='Elementary' 3='Junior' 4='Senior High' 5='College' 6='Graduate'; 
    value mar 1='Single' 2='Married' 3='Widowed' 4='Divorced'; /* Please note the use of capital letters in the formatted values */
run;
data homework_3;
    set homework;
    format edu edu. mar mar.;
    label edu='Educational Level' mar='Marital Status'; /* Please note the use of capital letters in the labels */
run;
proc freq data=homework_3;
    tables edu mar;
run;

or even simpler, this only requires one data set named HOMEWORK

filename refile_1 '/home/...';
proc import datafile=refile_1 out=homework dbms=xlsx; 
getnames=yes;
run;
proc format;
    value edu 1='Illiteracy' 2='Elementary' 3='Junior' 4='Senior High' 5='College' 6='Graduate'; 
    value mar 1='Single' 2='Married' 3='Widowed' 4='Divorced'; /* Please note the use of capital letters in the formatted values */
run;
proc datasets library=work nolist;
    modify homework;
    format mar mar. edu edu.;
    label edu='Educational Level' mar='Marital Status'; /* Please note the use of capital letters in the labels */
run;
quit;
proc freq data=homework;
    tables edu mar;
run;

Re: SAS proc format consequence problem

donricardo — Wed, 27 Sep 2023 16:27:49 GMT

Hi bbibi:

A few SAS procedures do not generate any reports by themselves, proc sort and proc format among them. The only way you'll know they've compiled is via a note in your log.

rich

Re: SAS proc format consequence problem

bbibbi_yc — Fri, 29 Sep 2023 06:19:15 GMT

Hello, thank you for your response. I followed your advice, but still couldn't achieve the results I expected.

Why weren't the numbers replaced in the form?

Thank u.

Re: SAS proc format consequence problem

bbibbi_yc — Fri, 29 Sep 2023 06:22:48 GMT

Hello, that means I can't see the 'Single' or other else in my table?

It sounds like a stupid question, but I really don't understand. Thank you for your patient response.

Re: SAS proc format consequence problem

Kurt_Bremser — Fri, 29 Sep 2023 08:27:46 GMT

@bbibbi_yc wrote:

Hello, thank you for your response. I followed your advice, but still couldn't achieve the results I expected.

Why weren't the numbers replaced in the form?

Because you did not use the formats in the FREQ procedure, as was already mentioned.

Please do not post pictures of code or logs in the future. Always (ALWAYS) copy/paste the text into the appropriate windows (see your "welcome" email when you signed up to the forum). This allows us to quickly annotate and correct your work.

Re: SAS proc format consequence problem

Tom — Fri, 29 Sep 2023 13:28:52 GMT

@bbibbi_yc wrote:

Hello, that means I can't see the 'Single' or other else in my table?

It sounds like a stupid question, but I really don't understand. Thank you for your patient response.

Formats impact how the value is DISPLAYED, not the value that is STORED.

So if you have a format that display the number 1 as the string Single then the number 1 is what is stored in the dataset. If the format is being used when you "look" at the data then you will see Single but the value in the dataset is still the number 1.

So in the tabular report (what I normally mean when I use the word TABLE) produced by PROC FREQ the formatted value is displayed. So if the variable has a format attached that converts 1 to Single then Single will show up in the report. If there is no format attached to a number than SAS will normally display it using the BEST12. format.

Re: SAS proc format consequence problem

Reeza — Fri, 29 Sep 2023 15:03:08 GMT

Post the log as well to indicate if something went wrong somewhere.

Also, test this use case which should work.

proc format;
value $ sex_fmt
'F' = 'Female'
'M' = 'Male';

value age_fmt
low - 9 = 'Child'
10-12 = 'Tween'
13-16 = 'Teen'
16 - high = 'Young Adult';
run;

data class;
set sashelp.class;
format age age_fmt. sex $sex_fmt.;
run;

proc freq data=class;
tables age sex;
run;

@bbibbi_yc wrote:

Hello, thank you for your response. I followed your advice, but still couldn't achieve the results I expected.

Why weren't the numbers replaced in the form?

Thank u.

Re: SAS proc format consequence problem

Reeza — Fri, 29 Sep 2023 15:04:59 GMT

@Kurt_Bremser wrote:

@bbibbi_yc wrote:

Hello, thank you for your response. I followed your advice, but still couldn't achieve the results I expected.

Why weren't the numbers replaced in the form?

Because you did not use the formats in the FREQ procedure, as was already mentioned.

Please do not post pictures of code or logs in the future. Always (ALWAYS) copy/paste the text into the appropriate windows (see your "welcome" email when you signed up to the forum). This allows us to quickly annotate and correct your work.

If the formats are applied at the data set level, proc freq should be using them. Either it's a language incompatibility issue or there's an error in the log somewhere we can't see are my guesses. For language incompatibility, I've seen SAS Studio not work correctly in Chinese keyboard/dialects.

Re: SAS proc format consequence problem

ballardw — Fri, 29 Sep 2023 15:13:36 GMT

@bbibbi_yc wrote:

Hello, that means I can't see the 'Single' or other else in my table?

It sounds like a stupid question, but I really don't understand. Thank you for your patient response.

WHICH dataset (not table at this point). You have at least two data sets shown in a picture of your code.

SAS variables always have a format assigned. The format controls how SAS will display the values by default. In many cases for numeric values you SAS will default to something like BEST12. , which means it will make an attempt to display the value in 12 characters. IF you create a custom format and permanently assign it to a variable then the format has to be available to the current session for use, otherwise SAS will fall back on the default. To have a custom format available in a session you either have to run the code to recreate the format OR create the format(s) in a permanent library that is active and add the path to that format storage with the SAS option FMTSEARCH, which tells SAS where to look for formats in addition to the SAS default formats. For beginning SAS users I recommend rerunning the format code.

There is actually a SAS option that will prevent use of a data set with a custom format that SAS can't find. An example from my LOG setting the option and then attempting to use a format that is not defined:

52   options fmterr;
53
54   proc freq data=sashelp.class;
55      tables sex;
56      format sex $mysexformat.;
ERROR: The format $MYSEXFORMAT was not found or could not be loaded.
57   run;

Re: SAS proc format consequence problem

bbibbi_yc — Sun, 01 Oct 2023 02:34:50 GMT

I see. Thanks for your opinion!

Re: SAS proc format consequence problem

bbibbi_yc — Sun, 01 Oct 2023 03:06:22 GMT

/*import data*/
Filename refile_1 '/home/u63518324/sasuser.v94/Epi_test.xls';
proc import datafile=refile_1
out=homework
dbms=xls;
getnames=yes;
run;

/*change label, format*/

proc format;
    value edu 1='Illiteracy' 2='Elementary' 3='Junior' 4='Senior High' 5='College' 6='Graduate'; 
    value mar 1='Single' 2='Married' 3='Widowed' 4='Divorced';
run;
data homework_3;
    set homework;
    format edu edu. mar mar.;
    label edu='Educational Level' mar='Marital Status';
run;
options nofmterr;
proc freq data=homework_3;
    tables edu mar;
run;

Hello, this is my code. I'm wondering where the problem is that prevents me from opening my data display results. Also, the following error still appears in the log.

 85             format edu edu. mar mar.;
                           ____
                           484
 NOTE 484-185: Format $EDU was not found or could not be loaded.
 
 85       !     format edu edu. mar mar.;
                                    ____
                                    484
 NOTE 484-185: Format $MAR was not found or could not be loaded.

Thank u so much.

Re: SAS proc format consequence problem

Tom — Sun, 01 Oct 2023 03:23:51 GMT

So that means that EDU and MAR were created as CHARACTER variables by PROC IMPORT.

If you expected them to be numeric then you need to look at the XLS file and find out why they are not numeric.

Or you could change the format definition to define a character format.

Example:

value $mar '1'='Single' '2'='Married' '3'='Widowed' '4'='Divorced';

But be careful because the string '1' and the string ' 1' are two different strings.

Re: SAS proc format consequence problem

bbibbi_yc — Sun, 01 Oct 2023 14:25:16 GMT

It's indeed not in numerical form. Thank you very much for helping me identify the problem. I'm sorry for taking up so much of everyone's time.