proc sgplot. no color in legend to match bar graph

HitmonTran — Tue, 26 Sep 2023 05:08:44 GMT

Hello,

my legend does not have any colors to match with the bargraph. not sure how to fix it

output:

code:

proc sgplot data=graph;

	vbar var/response=varn    group=txt groupdisplay=cluster;
	 label varn='% of Patients'
		  var=''
		  txt='Visit Time';  

	 legenditem type=FILL name='Baseline' /label='Baseline (N=&two1n)'  ;
	 legenditem type=FILL name='Usage' /label='60-Month followup (N=&two2n)';
	keylegend  "Baseline" "Usage";
run;

Re: proc sgplot. no color in legend to match bar graph

yabwon — Tue, 26 Sep 2023 06:32:17 GMT

#Maxim1

https://documentation.sas.com/doc/en/pgmsascdc/v_043/grstatproc/p0hc32jtfqoy1fn1h5i38q8v9py2.htm#n00jwj7lumri74n15g2aezqm8f3h

Also use attrmap top be sure that colors "match": https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/p18q268a3zxcl3n11lnnnq4cme8r.htm

data attrmapfruit;
retain linecolor "black";
input id $ value $ fillcolor $;
datalines;
sex F red
sex M blue
;
run;



proc sgplot data=sashelp.class dattrmap=attrmapfruit;

	vbar age/response=height group=sex groupdisplay=cluster attrid=sex;

  label height='height label'
		  sex='sex label'
		  age='age label';  

	 legenditem type=FILL name='F' / FILLATTRS=(color=red) label='F label';
	 legenditem type=FILL name='M' / FILLATTRS=(color=blue) label='M label' ;
	keylegend  "F" "M";
run;

Bart

topic Re: proc sgplot. no color in legend to match bar graph in SAS Programming

proc sgplot. no color in legend to match bar graph

Re: proc sgplot. no color in legend to match bar graph