topic Re: Replace all characters with x except last 4 four in SAS Programming

Replace all characters with x except last 4 four

nickspencer — Thu, 07 Sep 2023 02:55:16 GMT

Hello All,
I have a SAS dataset with account numbers(character). I want to display only last 4 masking the remaining with ‘x’.

Input:
Account
123456
34567898

Output:
Account
xx3456
xxxx7898

Any suggestions will be highly appreciated.

Re: Replace all characters with x except last 4 four

ballardw — Thu, 07 Sep 2023 03:57:11 GMT

What do you want if the length of the account is less than or equal to 4 characters?

Is the Account numeric or character?

If account is character valued and leave the account alone if there are 4 or fewer characters:

data have;
input Account :$10.;
datalines;
123456
34567898
1234
;

data want;
   set have;
   if length(account) ge 5 then 
       account = cats(repeat('x',length(account)-5),substr(account,length(account)-3));
run;

Please not the use of a data step to provide some working values. That way we don't have to ask questions like is the Account numeric or character.

CATS concatenates string values ignoring leading and trailing spaces, Repeat will create the same character a number of times look at the documentation as to why the -5 gets involved.Length returns the number characters excluding trailing spaces. Substr selects a number of characters from a given starting position in the string. If there is no length it uses from the given position to the end of the string. Again look at the values for why -3 is used instead of -4.

This is only one way.

Re: Replace all characters with x except last 4 four

andreas_lds — Thu, 07 Sep 2023 06:37:14 GMT

Assuming that account is a char variable, as it should be:

data want;
   set have;

   if lengthn(account) > 4 then do;
      new = cats(repeat('x', lengthn(account)-5), prxchange('s/.*(.{4})$/$1/', 1, trim(account)));
   end;
run;

Re: Replace all characters with x except last 4 four

Kurt_Bremser — Thu, 07 Sep 2023 08:06:45 GMT

Brute force method:

do i = 1 to length(account) - 4;
  substr(account,i,1) = "x";
end;

Re: Replace all characters with x except last 4 four

LinusH — Thu, 07 Sep 2023 08:12:42 GMT

If this is/becomes a comon practice at your site, you might want to look into adding masking capabilities to your infrastructure.

On SAS9 this is managed in Federation Server or DQ/QKB.

There are also external databases that offers this in the data layer, wich is more flexible than hard rewrite of values.

Re: Replace all characters with x except last 4 four

RichardAD — Thu, 07 Sep 2023 08:46:53 GMT

You can use a left-hand side SUBSTR to replace characters.

  accnom = accno;
  substr(accnom,1,length(accnom)-4) = repeat('*',length(accnom));