topic more efficient way to perform merge-proc sql or data step in SAS Programming

more efficient way to perform merge-proc sql or data step

Ronein — Mon, 04 Sep 2023 20:11:31 GMT

Hello

What is more efficient way to perform merge?

proc sql or data step? and why?

 /***Way1-Proc sql****/
proc sql;
create table want1 as
select a.*,b.Numerator 
from t1 as a
left join t2  as b
on a.Customer_id=b.Customer_id  and a.branch_ID=b.branch_ID
;
quit;


/***Way2-Data Step****/
proc sort data=t1;
by Customer_id branch_ID;
Run;
proc sort data=t2;
by Customer_id branch_ID;
Run;
Data want;
Retain Numerator;
Merge t1(in=a) t2(in=b);
by Customer_id branch_ID;
if a;
Run;

Re: more efficient way to perform merge-proc sql or data step

Kurt_Bremser — Mon, 04 Sep 2023 20:53:58 GMT

Run both steps and look at the log. You may need sufficiently large datasets to see a difference.

If t2 (using only the three variables needed) can fit into memory, a single DATA step with a hash object will be most efficient:

data want;
set t1;
if _n_ = 1
then do;
  length numerator /* insert proper attribute here */;
  declare hash t2 (dataset:"t2 (keep=customer_id branch_id numerator)");
  t2.definekey("customer_id","branch_id");
  t2.definedata("numerator");
  t2.definedone();
  call missing("numerator");
end;
rc = t2.find();
drop rc;
run;

Re: more efficient way to perform merge-proc sql or data step

Ronein — Tue, 05 Sep 2023 10:31:34 GMT

Let's say that t2 data set is located in permanent library r_r.

so the data set name is r_r.t2

does it mean that I need to write r_r.t2 in your code instead of t2?

Re: more efficient way to perform merge-proc sql or data step

Kurt_Bremser — Wed, 06 Sep 2023 05:59:30 GMT

@Ronein wrote:

does it mean that I need to write r_r.t2 in your code instead of t2?

Correct.

Re: more efficient way to perform merge-proc sql or data step

ballardw — Tue, 05 Sep 2023 20:47:07 GMT

Any discussion of "efficient" should include a definition of what is measured and how it is used to determine efficiency. If you don't provide something to measure how do you know if something is "more efficient".

Programming time

Program maintenance

Single Run time

Data storage space

Network traffic

Just a few different things that might be considered in "efficient".