topic Re: Wrong calculation in SAS Programming

Wrong calculation

Ronein — Tue, 29 Aug 2023 08:30:34 GMT

Hello

I run this code but I see that there is wrong calculation of variable "a".

May anyone explain why did it happen and what is the way to solve it?

%let YYMM1=2302; 
%let YYMM2=2306;
 
data t1;
     %let start = %sysfunc(inputn(&YYMM1.,yymmn4.));
     %let end   = %sysfunc(inputn(&YYMM2.,yymmn4.));
     call symput("n",trim(left(intck('month',&start.,&end.))));
	 a=&n.;
	 b=MOD(&n.,2);
	 c=&YYMM1.;
	 d=&YYMM2.;
run;
/****Varaible a should get value 4!!!!***/


%let YYMM1=2303; %let YYMM2=2306; 
data t2;
     %let start = %sysfunc(inputn(&YYMM1.,yymmn4.));
     %let end   = %sysfunc(inputn(&YYMM2.,yymmn4.));
     call symput("n",trim(left(intck('month',&start.,&end.))));
	 a=&n.;
	 b=MOD(&n.,2);
	 c=&YYMM1.;
	 d=&YYMM2.;
run;
/****Varaible a should get value 3 but I see value 4!!!!***/

Re: Wrong calculation

yabwon — Tue, 29 Aug 2023 09:32:09 GMT

Did you read the documentation about the "method" option and how it calculates?

[Edit:] Correct link:

https://documentation.sas.com/doc/en/vdmmlcdc/8.1/lefunctionsref/p1md4mx2crzfaqn14va8kt7qvfhr.htm#n1d9sidj5fym4un19eic1j3zx5hh

~~https://documentation.sas.com/doc/en/vdmmlcdc/8.1/ds2ref/n096g3nwx05g7wn161ax2rdqmlfn.htm#n121oubah6given17jzwtci4ptil~~

Bart

Re: Wrong calculation

Kurt_Bremser — Tue, 29 Aug 2023 09:31:48 GMT

Macro timing.

 
data t1;
     %let start = %sysfunc(inputn(&YYMM1.,yymmn4.));
     %let end   = %sysfunc(inputn(&YYMM2.,yymmn4.));
     call symput("n",trim(left(intck('month',&start.,&end.))));
	 a=&n.; /* this is resolved at compile time, so the value from CALL SYMPUT will not have an effect */
	 b=MOD(&n.,2); /* same */
	 c=&YYMM1.;
	 d=&YYMM2.;
run;

Re: Wrong calculation

yabwon — Tue, 29 Aug 2023 09:37:52 GMT

Kurt's right, with macro timing fixed it displays:

	 a=symgetn('n');
	 b=MOD(a,2);
	 c=symgetn('YYMM1');
	 d=symgetn('YYMM2');

Bart

Re: Wrong calculation

PaigeMiller — Tue, 29 Aug 2023 10:06:08 GMT

Instead of this:

     call symput("n",trim(left(intck('month',&start.,&end.))));
	 a=&n.;

(Why do you feel you need to create a macro variable &n here within a data step anyway, when a data step variable will do?)

use this:

 a=intck('month',&start.,&end.);

Re: Wrong calculation

Kurt_Bremser — Tue, 29 Aug 2023 10:01:29 GMT

And I would never use macro variables to keep values across actions in a data step. Within a single observation it is simple insanity, and across observations one uses RETAINed data step variables.

Re: Wrong calculation

Rick_SAS — Tue, 29 Aug 2023 12:52:19 GMT

Perhaps this is intentionally an exercise on macro evaluation, but, if not, you might consider using the DATA step, which is faster, easier to debug, and more versatile. Perhaps something like this?

%let YYMM1=2302; 
%let YYMM2=2306;
 
data t1;
    format start end DATE9.;
    start = inputn("&YYMM1.",'yymmn4.');
    end   = inputn("&YYMM2.",'yymmn4.');
    n = intck('month',start,end);
   a=n;
   b=MOD(n,2);
   c=&YYMM1.;
   d=&YYMM2.;
run;