topic Re: Display of headers in table using proc report in SAS Programming

Display of headers in table using proc report

ANKH1 — Wed, 12 Jul 2023 14:40:06 GMT

Hi,

We want to produce a table where the first column header is aligned to the left but the second column header is centered. I have this code and I don't know how to change it to get the display I want. How can you modify? I am not familiar with proc report.

proc report data= dsin nowd missing split = '~'
style(report)={frame=box}
style(header)={font=('Times New Roman', 8 pt) just=center background=lightgrey}
style(column)={font=('Times New Roman', 8 pt) just=left};
column label sample;
define label / display "This is a header" style(column)={just=left cellwidth = 12.0 cm asis=on};
define sample / display "sample" style(column)={just=center cellwidth = 3 cm};
run;

Re: Display of headers in table using proc report

A_Kh — Wed, 12 Jul 2023 15:44:13 GMT

You should use style (header)= attributes in the define statements (which is individual) and remove justifications from the proc report statement (which is general).

proc report data= dsin nowd missing split = '~'
style(report)={frame=box}
style(header)={font=('Times New Roman', 8 pt) background=lightgrey}
style(column)={font=('Times New Roman', 8 pt) };
column label sample;
define label / display "This is a header" style(header)= {just=left} style(column)={just=left cellwidth = 12.0 cm asis=on};
define sample / display "sample" style(header)= {just=center} style(column)={just=center cellwidth = 3 cm};
run;

Re: Display of headers in table using proc report

data_null__ — Wed, 12 Jul 2023 15:45:18 GMT

define label / display "This is a header" style(column)={just=left cellwidth = 12.0 cm asis=on};
define sample / display "sample" style(column)={just=center cellwidth = 3 cm};

Try this. Remove the location qualifier (column) from your style overrides in the DEFINE statement.

define label / display "This is a header" style={just=left cellwidth = 12.0 cm asis=on};
define sample / display "sample" style={just=center cellwidth = 3 cm};

Re: Display of headers in table using proc report

ballardw — Wed, 12 Jul 2023 15:47:32 GMT

Not a very clear description of what you want. Do actually want the second column centered or not?

Hard to test code without data.

You can override procedure level settings in the Display statement:

define label / display "This is a header" style(column)={just=left cellwidth = 12.0 cm asis=on}
                                          style(header)={just=left}
;

for example changes the HEADER setting for Label to left justify leaving other settings alone.

Re: Display of headers in table using proc report

ANKH1 — Wed, 12 Jul 2023 16:01:50 GMT

Thank you for replying!

Re: Display of headers in table using proc report

ANKH1 — Wed, 12 Jul 2023 16:02:09 GMT

Thank you!