topic Re: informat datetime in SAS Programming

informat datetime

Ronein — Sun, 09 Jul 2023 08:47:04 GMT

Hello

I want to create data set by enter the data.

What is the way to define the informat for data set "Have1"?

Note- Informat for data set "Have2" is working well

data have1;
input d_time : datetime18.;
format d_time datetime20.;
cards;
27/05/2023:06:05:00
03/10/2022:14:24:00
02/10/2022:20:19:00
;
Run;

data have2;
input d_time : datetime18.;
format d_time datetime20.;
cards;
27MAY2023:06:05:00
03OCT2022:14:24:00
02OCT2022:20:19:00
;
Run;

Re: informat datetime

PaigeMiller — Sun, 09 Jul 2023 10:35:20 GMT

What is wrong with your code? Please explain. If there are problems in the log, show us the ENTIRE log (not the first time we have asked). If the output is wrong, tell us in words what you are seeing that is incorrect.

Re: informat datetime

Tom — Sun, 09 Jul 2023 12:14:40 GMT

You could try the ANYDTDTM informat.

678  data have1;
679  input d_time : anydtdtm.;
680  format d_time datetime20.;
681  put d_time _infile_;
682  cards;

27MAY2023:06:05:00 27/05/2023:06:05:00
10MAR2022:14:24:00 03/10/2022:14:24:00
10FEB2022:20:19:00 02/10/2022:20:19:00
NOTE: The data set WORK.HAVE1 has 3 observations and 1 variables.

But you will notice that for the ambiguous records where the first value could be either the month or the day of the month (at least on my machine) it defaults to use MDY ordering.

If you want to force it to use DMY order in those ambiguous situations then you need to se the datestyle option.

690  options datestyle=dmy;
691  data have1;
692  input d_time : anydtdtm.;
693  format d_time datetime20.;
694  put d_time _infile_;
695  cards;

27MAY2023:06:05:00 27/05/2023:06:05:00
03OCT2022:14:24:00 03/10/2022:14:24:00
02OCT2022:20:19:00 02/10/2022:20:19:00
NOTE: The data set WORK.HAVE1 has 3 observations and 1 variables.

Re: informat datetime

Kurt_Bremser — Sun, 09 Jul 2023 12:31:18 GMT

data have1;
input d ddmmyy10. @12 t time8.;
d_time = dhms(d,0,0,t);
format d_time datetime20.;
drop d t;
cards;
27/05/2023:06:05:00
03/10/2022:14:24:00
02/10/2022:20:19:00
;