topic Re: How do I display categories with no observation? in SAS Programming

How do I display categories with no observation?

JDS1 — Thu, 22 Jun 2023 13:20:08 GMT

Hi,

which code do I have to use to ask SaS 9.4 to display all categories of a variable in a table even though some categories have no observation?

(f.e.: variable 'gender' with the categories "female", "male", "divers", "optout", "missing") and no person used the category "optout").

I did manage to generate a format (gender.) so all categories are defined, but I havent found a solution where or how use the defined format (gender.) in a proc to display responses to ALL categories; (especially for the proc freq, proc print, proc tabulate - so really basic steps).

Thanks in advance.

JDS1

Re: How do I display categories with no observation?

Ksharp — Thu, 22 Jun 2023 14:12:15 GMT

Here is an example for PROC FREQ:

data have;
 set sashelp.heart end=last;
 w=1;output;
 if last then do;w=0;sex='NA';output;end;
run;

proc freq data=have;
table sex;
weight w/zero;
run;

Re: How do I display categories with no observation?

ballardw — Thu, 22 Jun 2023 14:43:15 GMT

Procs Means/Summary, Report and Tabulate have an option PRELOADFMT that will report on categories of class variables using the defined format.

proc tabulate data=yourdata;
   class gendervar / preloadfmt ;
   format gendervar gender. ;
   table gendervar, 
           n
           /printmiss;
run;

Each procedure that uses Preloadfmt has slight differences on how it must be used and there are some interactions between them. Proc Tabulate for example requires one of table Printmiss option, or Order=data Class statement option or use of a CLASSDATA data set. Using multiple of these the order of the data display may change.

Check each procedure for details.

Re: How do I display categories with no observation?

JDS1 — Fri, 23 Jun 2023 05:30:57 GMT

Thank you so much! It worked

Re: How do I display categories with no observation?

JDS1 — Fri, 23 Jun 2023 05:31:42 GMT

Thanks! I will try out the w/zero option as well!

Re: How do I display categories with no observation?

JDS1 — Mon, 26 Jun 2023 08:08:08 GMT

Hi, unfortunately this code (with w/zero in proc freq) didn't work out for my data.