topic Re: loop for changing variables in changing datasets in SAS Programming

loop for changing variables in changing datasets

Konkordanz — Wed, 14 Jun 2023 10:39:26 GMT

Hi,

I have a problem and Im thankful for help.

Given is the data set "final". Today, for example, it contains 3 variables, but it could also have 5 or 10 variables the next time it is created. The names of the variables are always freely selectable and have no logic. But they all have one thing in common: The first variable is always "Eink" with the same characteristics and the goal is calculating a median (based on the groups in "Eink").

For the current dataset I have written a syntax for calculating the median. I attached the current syntax below. Based on my current dataset, Bg and He were used there. My problem is: If the record "final" appears tomorrow with other variables, the syntax should adapt individually to it. If tomorrow "Bg" and "He" no longer exist, but for example XX, XY and XZ, then the syntax should automatically be applied to these three variables with their specific names. So I probably need a loop, but am unable to write it. Could anyone help me with this big concern? Would be great!

dataset "final" given

Eink	Bg	He
01	55.487739	2.722371
02	127.485645	18.670678
03	182.95309	53.529988
04	354.69612	122.703093
05	450.777081	137.596942
06	461.617933	157.457164
07	429.38197	192.283645
08	370.644235	173.688658
09	281.256479	180.848677
10	170.426973	137.045263
11	118.22022	128.45571
12	93.656461	104.596442
13	68.561622	112.710123
14	42.443895	77.742469
15	50.933162	136.718895
16	35.285987	104.219131
17	23.123863	78.424041
18	16.724659	89.48717
19	9.271308	46.396113
20	4.870804	21.574738
21	4.83902	19.753305
22	3.487616	9.23105
23	0.860551	2.136266
24	1.202043	1.861731

code


/*1*/

Data Eink_2;
set final;
if Eink = "01" then do; 	Xmin = 	0		; Xmax = 	250		; end;
if Eink = "02" then do; 	Xmin = 	250		; Xmax = 	500		; end;
if Eink = "03" then do; 	Xmin = 	500		; Xmax = 	750		; end;
if Eink = "04" then do; 	Xmin = 	750		; Xmax = 	1000	; end;
if Eink = "05" then do; 	Xmin = 	1000	; Xmax = 	1250	; end;
if Eink = "06" then do; 	Xmin = 	1250	; Xmax = 	1500	; end;
if Eink = "07" then do; 	Xmin = 	1500	; Xmax = 	1750	; end;
if Eink = "08" then do; 	Xmin = 	1750	; Xmax = 	2000	; end;
if Eink = "09" then do; 	Xmin = 	2000	; Xmax = 	2250	; end;
if Eink = "10" then do; 	Xmin = 	2250	; Xmax = 	2500	; end;
if Eink = "11" then do; 	Xmin = 	2500	; Xmax = 	2750	; end;
if Eink = "12" then do; 	Xmin = 	2750	; Xmax = 	3000	; end;
if Eink = "13" then do; 	Xmin = 	3000	; Xmax = 	3250	; end;
if Eink = "14" then do; 	Xmin = 	3250	; Xmax = 	3500	; end;
if Eink = "15" then do; 	Xmin = 	3500	; Xmax = 	4000	; end;
if Eink = "16" then do; 	Xmin = 	4000	; Xmax = 	4500	; end;
if Eink = "17" then do; 	Xmin = 	4500	; Xmax = 	5000	; end;
if Eink = "18" then do; 	Xmin = 	5000	; Xmax = 	6000	; end;
if Eink = "19" then do; 	Xmin = 	6000	; Xmax = 	7000	; end;
if Eink = "20" then do; 	Xmin = 	7000	; Xmax = 	8000	; end;
if Eink = "21" then do; 	Xmin = 	8000	; Xmax = 	10000	; end;
if Eink = "22" then do; 	Xmin = 	10000	; Xmax = 	15000	; end;
if Eink = "23" then do; 	Xmin = 	15000	; Xmax = 	25000	; end;
if Eink = "24" then do; 	Xmin = 	25000	; Xmax = 	.		; end;
run;

/*2*/

Data Eink_3;
set Eink_2;
cum_Bg+Bg;
cum_He+He;
run;


/*3*/

proc sql noprint;
select sum(Bg)/2 		into: n2_B	from Eink_3;
select sum(He)/2 		into: n2_H	from Eink_3;
run;



/*4*/

data Eink_4;
set Eink_3;
Fx_prä_B = 	&n2_B. - cum_Bg;
Fx_prä_H = 	&n2_H. - cum_He;
run;


/*5*/

	proc rank data=Eink_4 out=fx_1_Rang_B; 	var Fx_prä_B; 	ranks rang ; where Fx_prä_B >0;
	proc rank data=Eink_4 out=fx_1_Rang_H; 	var Fx_prä_H; 	ranks rang ; where Fx_prä_H >0;


/*6*/

	proc sql noprint; select put(cum_Bg, decimal.7) 	into:Fx_1_B from fx_1_Rang_B 	where rang =1; quit;
	proc sql noprint; select put(cum_He, decimal.7) 	into:Fx_1_H from fx_1_Rang_H 	where rang =1; quit;



/*7*/

	proc rank data=Eink_4 descending out=fx_B; 	var Fx_prä_B; 	ranks Rang; where Fx_prä_B <0;
	proc rank data=Eink_4 descending out=fx_H; 	var Fx_prä_H; 	ranks Rang; where Fx_prä_H <0;


/*8*/

	proc sql noprint;
	select put(Bg, decimal.7) 	into:fx_B 	from fx_B where rang=1;
	select put(He, decimal.7) 	into:fx_H 	from fx_H where rang=1;
	run;


/*9*/

proc sql noprint;
select Xmin into: Xmin_B from fx_B where Rang = 1;
select Xmin into: Xmin_H from fx_H where Rang = 1;
quit;


/*10*/

proc sql noprint;
select Xmax-Xmin into: b_B 	from fx_B 	where Rang = 1;
select Xmax-Xmin into: b_H 	from fx_H 	where Rang = 1;
quit;



/*11 - into the formula */

Data Median_Final;
retain Eink Bg He;
Format 
Bg 15.12
He 15.12;
Eink 	= "Median";
Bg =	&Xmin_B.  	+ &b_B.*((&n2_B.-&Fx_1_B.)/&fx_B.);
He 	=	&Xmin_H.  	+ &b_H.*((&n2_H.-&Fx_1_H.)/&fx_H.);
run;

Re: loop for changing variables in changing datasets

Kurt_Bremser — Wed, 14 Jun 2023 09:54:45 GMT

Transpose to long, so you can use the _NAME_ variable as additional CLASS in PROC MEANS or ACROSS in PROC REPORT. If eink is the only character variable, you can use _NUMERIC_ in the VAR statement of TRANSPOSE.

Re: loop for changing variables in changing datasets

Konkordanz — Wed, 14 Jun 2023 10:12:52 GMT

Hmm, wouldnt be the best idea, because I have a total of 11 steps, which each create their own temporary datasets. As an example, I'll supplement my code snippet from above with the subsequent step of my syntax. So they always refer to each other.

I would like to apply these 11 steps as a loop. The code snippet was just one of these 11 on which the macro could be exemplified. I'll try to include the rest then.

Re: loop for changing variables in changing datasets

PaigeMiller — Wed, 14 Jun 2023 10:22:02 GMT

Yes, please show us, because the suggestion from @Kurt_Bremser ought to work on the 11 different steps.

Re: loop for changing variables in changing datasets

Konkordanz — Wed, 14 Jun 2023 10:41:37 GMT

I have fleshed out my initial post above and added my syntax that works based on the current data set (but I have reformulated/anonymized the syntax a bit). I hope this doesn't make too much work. Thanks!

Re: loop for changing variables in changing datasets

PaigeMiller — Wed, 14 Jun 2023 11:38:56 GMT

It looks like you are computing some sort of a median, using sums, max, min for each "half" of the data, and then plugging these into a formula. I would think there are better/faster ways to do this that don't involve macros or macro variables, but I don't fully understand the process or the end result. Could you please explain what you are trying to do?

Re: loop for changing variables in changing datasets

ballardw — Wed, 14 Jun 2023 15:02:34 GMT

@Konkordanz wrote:

Hmm, wouldnt be the best idea, because I have a total of 11 steps, which each create their own temporary datasets. As an example, I'll supplement my code snippet from above with the subsequent step of my syntax. So they always refer to each other.

I would like to apply these 11 steps as a loop. The code snippet was just one of these 11 on which the macro could be exemplified. I'll try to include the rest then.

If you have a data set with a grouping variable and want to create summary statistics for numeric variables then proc means/summary is likely where you belong. Splitting data into separate data sets just to get a median of a value is just "wrong" in a SAS approach.

Here is a small example with a data set you should have available to examine.

Proc summary data=sashelp.class nway;
   class sex;
   var _numeric_;
   output out=want (drop=_type_ _freq_)
        median = ;
run;

The option NWAY is to just show the result for the highest _type_ value of the result. _Type_ indicates which combination(s) of Class variables are involved in an output observation. The default output would also include an overall summary for all observations and if more variables are involved on the class statement then there multiple combinations possible.

Class indicates your grouping variable.

Var is list of numeric variables to use. In this case _numeric_ uses all of the numeric variables in the data set (there are only 3).

The output statement names the output dataset and requests which statistic(s) to create. The drop removes two automatic variables that would appear by default. The Median= requests the median statistic. With a single statistic that means the output statistic has the same name as the input variable. You can either name the resulting statistic your self or use /autoname option to create names with the statistic appended.

Re: loop for changing variables in changing datasets

Konkordanz — Thu, 15 Jun 2023 06:17:11 GMT

The goal is to calculate a weigthed median, based on a formular from the institution Im working for. With the 11 steps I calculate each component of the formular:

- Xmin_B and Xmin_H

- b_B and b_H

- n2_B and n2_H

- Fx_1_B and Fx_1_H

- fx_B and fx_H

At the end, I put these components into the formula and calculate the median (step 11). That works pretty well. But with new variables I always have to manually adjust the syntax. And my hope is, that there is a solution like a loop...

Re: loop for changing variables in changing datasets

Konkordanz — Fri, 16 Jun 2023 05:19:40 GMT

Thx for answering. I wouldnt say "wrong", because I dont calculate an default median. I have to calculate a median based on a formular of the institution Im working for. I have fleshed out my initial post above.

Re: loop for changing variables in changing datasets

Kurt_Bremser — Fri, 16 Jun 2023 05:38:55 GMT

With such a complex process which can't use the available SAS procedures, you have to feed a list of variables to a macro and use %DO loops to create the repeating code wherever needed.

You can create multiple macro variables in a single SELECT INTO, so use that to speed up your process.

Similarly, avoid to run multiple steps for each variable; in most cases, you can process multiple variables in a single step.

Re: loop for changing variables in changing datasets

Tom — Fri, 16 Jun 2023 17:56:35 GMT

Looks to me like your first 4 steps are just these two steps. Plus I generated SIGN variables that can probably be used to reduce the PROC RANK steps to one instead of two.

data final ;
  input Eink :$2. Bg He ;
cards;
01 55.487739 2.722371
02 127.485645 18.670678
03 182.95309 53.529988
04 354.69612 122.703093
05 450.777081 137.596942
06 461.617933 157.457164
07 429.38197 192.283645
08 370.644235 173.688658
09 281.256479 180.848677
10 170.426973 137.045263
11 118.22022 128.45571
12 93.656461 104.596442
13 68.561622 112.710123
14 42.443895 77.742469
15 50.933162 136.718895
16 35.285987 104.219131
17 23.123863 78.424041
18 16.724659 89.48717
19 9.271308 46.396113
20 4.870804 21.574738
21 4.83902 19.753305
22 3.487616 9.23105
23 0.860551 2.136266
24 1.202043 1.861731
;

data min_max ;
  length Eink $2  Xmin Xmax 8;
  do xmax = 250 to 3500 by 250,4000,4500,5000,6000,7000,8000,10000,15000,25000,. ;
     i+1;
     eink=put(i,z2.);
     xmin=sum(0,lag(xmax));
     output;
  end;
  drop i;
run;

proc summary data=FINAL ;
  var Bg He ;
  output out=sums(drop=_freq_ _type_) sum=sum_Bg sum_He ;
run;

data STEP4;
  merge final min_max ;
  by eink;
  if _n_=1 then set sums;
  cum_Bg + Bg;
  Fx_Bg = 	sum_bg/2 - cum_Bg;
  Sign_Bg = sign(fx_bg);
  cum_He + He;
  Fx_He = sum_he/2 - cum_He;
  Sign_He = sign(fx_he);
run;

So if Bg and He represent the variables you need to process then you might use macro code to generate those blocks that use them.

... 
sum=sum_Bg sum_He  ;
...
  cum_Bg + Bg;
  Fx_Bg = 	sum_bg/2 - cum_Bg;
  Sign_Bg = sign(fx_bg);
  cum_He + He;
  Fx_He = sum_he/2 - cum_He;
  Sign_He = sign(fx_he);
...

But you could also transpose the data first. Then no need to generate code (other than the list of variables in the VAR statement of the TRANSPOSE step).

proc transpose data=FINAL out=TALL(rename=(col1=VALUE)) name=VARNAME ;
  by Eink;
  var Bg He ;
run;

proc sort data=TALL;
  by varname eink;
run;

proc summary data=TALL nway;
  by varname ;
  var value;
  output out=sums(drop=_freq_ _type_) sum=sum_value ;
run;

data step4_tall;
  merge tall sums ;
  by varname ;
  if _n_=1 then do;
    set min_max;
    declare hash h(dataset:'min_max');
    h.definekey('eink');
    h.definedata('Xmin','Xmax');
    h.definedone();
  end;
  if first.varnum then cum_value=.;
  h.find();
  cum_value + value ;
  fx_value = sum_value/2 - cum_value ;
  Sign_value = sign(fx_value);
run;

Re: loop for changing variables in changing datasets

Tom — Fri, 16 Jun 2023 17:58:12 GMT

What is STEP5 to STEP11 doing?

Why is it using RANK instead of just taking the MIN and MAX?

proc summary data=step4_tall nway ;
  by varname sum_value ;
  class sign_value ;
  var cum_value fx_value ;
  output out=stats min= max= / autoname ;
run;
proc print;
run;

                                                             cum_                   cum_
                    sum_     Sign_                         value_    fx_value_     value_    fx_value_
Obs    VARNAME     value     value    _TYPE_    _FREQ_        Min       Min         Max         Max

 1       Bg       3358.21      -1        1        18      2062.40     -1679.10    3358.21      -383.30
 2       Bg       3358.21       1        1         6        55.49        46.09    1633.02      1623.62
 3       He       2109.85      -1        1        15      1176.55     -1054.93    2109.85      -121.62
 4       He       2109.85       1        1         9         2.72        15.43    1039.50      1052.20

Re: loop for changing variables in changing datasets

ballardw — Fri, 16 Jun 2023 18:12:58 GMT

At this point I think I am going call "Foul" on use of the word "median" at all to describe this process.

When I use that example data and run the code the result I get is

Obs     Eink                  Bg                 He

 1     Median    1526.8329804346    2278.1399438082

Every definition I have run into for median relates to "being in the middle" of values with some slop as to exactly how that middle is defined. Or perhaps "Formally, a median of a population is any value such that at least half of the population is less than or equal to the proposed median and at least half is greater than or equal to the proposed median."

Since the largest value in your Final example data for Bg is 461.6179330 I see no way that a value of 1526 or greater should be considered any sort of "median" for Bg. Similar with your He variable as the max in the set is 192.283645.

This may be a statistic of some sort but a median it ain't.

Re: loop for changing variables in changing datasets

Tom — Fri, 16 Jun 2023 18:31:47 GMT

So that last formula appears to interpolating between XMIN and XMAX based on the something that looks like perhaps the range at the point where the cum sum crosses the 50% point of the total sum.

Bg =	&Xmin_B.  	+ &b_B.*((&n2_B.-&Fx_1_B.)/&fx_B.);
He 	=	&Xmin_H.  	+ &b_H.*((&n2_H.-&Fx_1_H.)/&fx_H.);

Since you appear to have gotten it to run what are the values of those 5 macro variables for each analysis variable that ended up being used to make your result?

Since they appear from the convoluted steps 5 to 10 be just pulling values from the dataset we should be able to look at the numbers and figure out which values the formula is using (much easier than figuring out what that code is trying to pull from looking at it).

Re: loop for changing variables in changing datasets

Tom — Fri, 16 Jun 2023 18:43:16 GMT

For your example data what values did the macro variables used in that last step end up having?

Bg = &Xmin_B.   + &b_B.*((&n2_B.-&Fx_1_B.)/&fx_B.);
He  = &Xmin_H.   + &b_H.*((&n2_H.-&Fx_1_H.)/&fx_H.);

If you don't know re-run it with the SYMBOLGEN option turned on and the SAS log will show you.

Are they basically just the values from these rows where the value on the FX variable flips from positive to negative?

                                       sum_                       cum_                 Sign_
Obs    Eink    VARNAME     VALUE      value     Xmin    Xmax     value     fx_value    value

  6     06       Bg       461.618    3358.21    1250    1500    1633.02      46.087       1
  7     07       Bg       429.382    3358.21    1500    1750    2062.40    -383.295      -1

 33     09       He       180.849    2109.85    2000    2250    1039.50      15.426       1
 34     10       He       137.045    2109.85    2250    2500    1176.55    -121.620      -1

Re: loop for changing variables in changing datasets

Reeza — Fri, 16 Jun 2023 19:47:36 GMT

This gets you really close. You'll need to play around with the rounding to get an exact match.

data final;
    input Eink :$2. Bg He;
    cards;
01 55.487739 2.722371
02 127.485645 18.670678
03 182.95309 53.529988
04 354.69612 122.703093
05 450.777081 137.596942
06 461.617933 157.457164
07 429.38197 192.283645
08 370.644235 173.688658
09 281.256479 180.848677
10 170.426973 137.045263
11 118.22022 128.45571
12 93.656461 104.596442
13 68.561622 112.710123
14 42.443895 77.742469
15 50.933162 136.718895
16 35.285987 104.219131
17 23.123863 78.424041
18 16.724659 89.48717
19 9.271308 46.396113
20 4.870804 21.574738
21 4.83902 19.753305
22 3.487616 9.23105
23 0.860551 2.136266
24 1.202043 1.861731
;

data max_min;
    length Eink $2 Xmin Xmax 8;

    do xmax=250 to 3500 by 250, 4000, 4500, 5000, 6000, 7000, 8000, 10000, 15000, 
            25000, .;
        i+1;
        eink=put(i, z2.);
        xmin=sum(0, lag(xmax));
        output;
    end;
    drop i;
run;

data eink_2;
    merge final max_min;
    by eink;
run;

proc sort data=eink_2;
    by eink xmax xmin;
run;

proc sql noprint;
    select name into :var_list separated by " " from sashelp.vcolumn where 
        libname='WORK' and memname='EINK_2' and upcase(name) not in ('EINK', 'XMAX', 
        'XMIN');
quit;

%put &var_list.;

proc transpose data=eink_2 out=tall(rename=(col1=VALUE)) name=VARNAME;
    by Eink xmax xmin;
    var &var_list;
run;

proc sort data=tall;
    by varname eink;
run;

*calculate cumulative sum;

data eink_3;
    set tall;
    by varname;

    if first.varname then
        cum_sum=value;
    else
        cum_sum+value;
run;

*get totals and substract from cumulative numbers;

proc sql;
    create table eink_4 as select varname, value, xmin, xmax, cum_sum, 
        sum(value)/2 as sum_var, calculated sum_var - cum_sum as fx_pra from eink_3 
        group by varname order by varname, eink;
quit;

*rank data ( really just reverses eink order for everything greater than 0?);

proc rank data=eink_4 out=ranked_data;
    where fx_pra>0;
    by varname;
    var fx_pra;
    ranks rang;
run;

*get first ranks only;

data first_ranks;
    set ranked_data;
    where rang=1;
    cum_sum=round(cum_sum, 0.0000001);
    keep varname value sum_var cum_sum;
run;

*repeat rank process for >0;
*rank data ( really just reverses eink order for everything greater than 0?);

proc rank data=eink_4 descending out=ranked_data_reversed;
    where fx_pra<0;
    by varname;
    var fx_pra;
    ranks rang;
run;

*get first ranks only;

data first_ranks_reversed;
    set ranked_data_reversed;
    where rang=1;
    B=xmax-xmin;
    value=round(value, 0.0000001);
    keep varname xmin B Value;
    rename xmin=reversed_xmin value=reversed_value;
run;

data results;
    merge first_ranks first_ranks_reversed;
    by varname;
    MEDIAN=reversed_xmin + B*((sum_var-cum_sum)/reversed_value);
    format MEDIAN 15.12;
run;

proc transpose data=results out=want NAME=EINK;
    id varname;
    var MEDIAN;
run;

Re: loop for changing variables in changing datasets

Tom — Sun, 18 Jun 2023 15:55:59 GMT

Thanks, @Reeza . So you just need to find the point where the cumulative sum crosses the 50% threshold.

@Konkordanz I don't think you need PROC RANK and that other stuff. And if you have explained what calculation you wanted:

* The MEDIAN is generated by interpolating between XMIN and XMAX ;
* Amount is based on how much of current value is before 50 percent ;

at the start we could have found a simple solution much faster.

Here is a macro that just needs the input dataset and the variable list and does it all in one data step. So you can run it for as many datasets and variables as you have.

(Note: The XMIN/XMAX values need to already be in the input dataset).

%macro adj_median
(indsn    /* Input dataset */
,varlist  /* space delimited variable list */
,outdsn=medians /* Output dataset */
);
%local n ;
%* Count how many variables there are ;
%let n=%sysfunc(countw(&varlist,%str( ),q));
data &outdsn ;
* Setup arrays ;
  array vars &varlist ;
  array total total1-total&n ;
  array subtot subtot1-subtot&n ;
  array median median1-median&n ;
* Calculate Totals ;
  do until(eof1);
    set &indsn end=eof1;
    do over vars;
      total+vars;
    end;
  end;
* Find 50 percent of totals ;
  do over total;
    total=total/2;
  end;
* Calculate cummulative total until cross half of total ;
* Continue until either hit the end of the data or have ;
* found median for every variable;
  do until(eof2 or n>=&n);
    set &indsn end=eof2;
    do over vars;
      subtot+vars;
      if subtot > total and missing(median) then do;
* The MEDIAN is generated by interpolating between XMIN and XMAX ;
* Amount is based on how much of current value is before 50 percent ;
        median = xmin + (xmax-xmin)*((total+vars-subtot)/vars) ;
        n+1;
      end;
    end;
  end;
* Store the medians back into the original variables;
  do over vars;
    vars = median;
  end;
* Only keep the original variables ;
  keep &varlist;
run;
%mend adj_median;

PS I don't like typing [i] over and over and over and over so I just made it use old fashion implicit array references.

So let's try if for our FINAL and MIN_MAX datasets.

data for_analysis;
  merge final min_max;
  by eink;
run;

options mprint;
%adj_median(indsn=for_analysis,varlist=Bg He,outdsn=WANT);

proc print data=want;
run;

Results

Obs       Bg         He

 1     1526.83    2278.14

Log

3648  options mprint;
3649  %adj_median(indsn=for_analysis,varlist=Bg He,outdsn=WANT);
MPRINT(ADJ_MEDIAN):   data WANT ;
MPRINT(ADJ_MEDIAN):   * Setup arrays ;
MPRINT(ADJ_MEDIAN):   array vars Bg He ;
MPRINT(ADJ_MEDIAN):   array total total1-total2 ;
MPRINT(ADJ_MEDIAN):   array subtot subtot1-subtot2 ;
MPRINT(ADJ_MEDIAN):   array median median1-median2 ;
MPRINT(ADJ_MEDIAN):   * Calculate Totals ;
MPRINT(ADJ_MEDIAN):   do until(eof1);
MPRINT(ADJ_MEDIAN):   set for_analysis end=eof1;
MPRINT(ADJ_MEDIAN):   do over vars;
MPRINT(ADJ_MEDIAN):   total+vars;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   * Find 50 percent of totals ;
MPRINT(ADJ_MEDIAN):   do over total;
MPRINT(ADJ_MEDIAN):   total=total/2;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   * Calculate cummulative total until cross half of total ;
MPRINT(ADJ_MEDIAN):   * Continue until either hit the end of the data or have ;
MPRINT(ADJ_MEDIAN):   * found median for every variable;
MPRINT(ADJ_MEDIAN):   do until(eof2 or n>=2);
MPRINT(ADJ_MEDIAN):   set for_analysis end=eof2;
MPRINT(ADJ_MEDIAN):   do over vars;
MPRINT(ADJ_MEDIAN):   subtot+vars;
MPRINT(ADJ_MEDIAN):   if subtot > total and missing(median) then do;
MPRINT(ADJ_MEDIAN):   * The MEDIAN is generated by interpolating between XMIN and XMAX ;
MPRINT(ADJ_MEDIAN):   * Amount is based on how much of current value is before 50 percent ;
MPRINT(ADJ_MEDIAN):   median = xmin + (xmax-xmin)*((total+vars-subtot)/vars) ;
MPRINT(ADJ_MEDIAN):   n+1;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   * Store the medians back into the original variables;
MPRINT(ADJ_MEDIAN):   do over vars;
MPRINT(ADJ_MEDIAN):   vars = median;
MPRINT(ADJ_MEDIAN):   end;
MPRINT(ADJ_MEDIAN):   * Only keep the original variables ;
MPRINT(ADJ_MEDIAN):   keep Bg He;
MPRINT(ADJ_MEDIAN):   run;

NOTE: There were 24 observations read from the data set WORK.FOR_ANALYSIS.
NOTE: There were 11 observations read from the data set WORK.FOR_ANALYSIS.
NOTE: The data set WORK.WANT has 1 observations and 2 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds

Re: loop for changing variables in changing datasets

Konkordanz — Tue, 20 Jun 2023 13:49:22 GMT

Oh, thank you for your effort and your responses! I will look at them in the coming days and get back to you. This will take a while because I need to get into your detailed answers and the many syntax steps that are new to me. Thanks!