topic Adding a trailing space to a character variable in SAS Programming

Adding a trailing space to a character variable

bayzid — Wed, 14 Jun 2023 05:48:09 GMT

I am trying add a leading and trailing space to a character variable using the following command.
caps=' '||caps;
caps=caps||' ';

It is adding a leading space but not the trailing space.

Re: Adding a trailing space to a character variable

Kurt_Bremser — Wed, 14 Jun 2023 06:17:24 GMT

Depending on the defined length (e.g. with a LENGTH statement) and the actual content, the variable will always have trailing blanks; strings in the variable are padded to the defined length with blanks.

Trailing blanks are usually not displayed, unless you force their display (e.g. by using the $CHAR format).

Re: Adding a trailing space to a character variable

bayzid — Wed, 14 Jun 2023 06:31:48 GMT

I have enough length in the variable. The source variable is 100 Char long and i am using the following

caps=put(GenericName,$upcase200.); /*Capitalise all letters and setting the length to 200*/
			caps = compbl(tranwrd(caps, ",", " ,")); /* Adding a space before a comma */
			caps = compbl(tranwrd(caps, ".", " ."));
			caps = compbl(tranwrd(caps, ";", " ;"));
			caps = compbl(tranwrd(caps, "&", " + "));
			*caps = compbl(tranwrd(caps, "/", " + "));
				caps=' '||caps;
				caps=caps||" ";

Re: Adding a trailing space to a character variable

Kurt_Bremser — Wed, 14 Jun 2023 06:50:06 GMT

So (unless you defined the length elsewhere) your new variable caps will be padded with blanks up to the 200th byte.

Re: Adding a trailing space to a character variable

bayzid — Wed, 14 Jun 2023 08:02:59 GMT

what is the solution then. I need to add a trailing space for text mining.

Re: Adding a trailing space to a character variable

Kurt_Bremser — Wed, 14 Jun 2023 08:06:21 GMT

Since there are already trailing spaces, there is no need to add any. The number of trailing spaces is always (defined length of variable) minus (position of last non-blank character).

Re: Adding a trailing space to a character variable

bayzid — Wed, 14 Jun 2023 08:09:00 GMT

But my following text mining command is not considering the trailing space.

pattern_id=prxparse('/( DONEPEZIL | GALANTAMINE | RIVASTIGMINE | MEMANTINE )/i');
	start=1;
	stop=length(caps);
	call prxnext(pattern_id, start, stop, caps, position, length);
	if (position>0)then
		cm_dementia=substr(caps, position, length);

Re: Adding a trailing space to a character variable

Kurt_Bremser — Wed, 14 Jun 2023 08:22:18 GMT

You don't need the blanks in the pattern IMO. See a similar solution here: https://communities.sas.com/t5/SAS-Programming/Searching-a-string-for-a-list-of-words/td-p/212899

Re: Adding a trailing space to a character variable

JosvanderVelden — Wed, 14 Jun 2023 09:06:31 GMT

If @Kurt_Bremser indications have not made it clear you can run the code below and analyze the output.

data want;
   length var1 $50 var2 $75 var3 $100 var4 $100;
   var1 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";
   var2 = "# " || var1;
   len_var2 = length(var2);
   var3 = var2 || " #";
   var4 = substr(var2, 1, len_var2) || " #";
   len_var3 = length(var3);
   len_var4 = length(var4);
run;

Re: Adding a trailing space to a character variable

originalshilaji — Wed, 14 Jun 2023 09:35:46 GMT

Your new variable caps will be padded with blanks up to the 200th byte, ensuring precise and consistent data storage.

Re: Adding a trailing space to a character variable

Tom — Wed, 14 Jun 2023 12:29:36 GMT

@bayzid wrote:

But my following text mining command is not considering the trailing space.

pattern_id=prxparse('/( DONEPEZIL | GALANTAMINE | RIVASTIGMINE | MEMANTINE )/i');
	start=1;
	stop=length(caps);
	call prxnext(pattern_id, start, stop, caps, position, length);
	if (position>0)then
		cm_dementia=substr(caps, position, length);

I assume it is not matching because you told PRXNEXT() to NOT use any of the trailing spaces by setting STOP to the last non-space character in the variable.

Re: Adding a trailing space to a character variable

bayzid — Wed, 14 Jun 2023 12:36:10 GMT

Everything is working when I am adding a dot at the end of the space.
caps1=' '||caps1;
caps=caps1||" .";

Re: Adding a trailing space to a character variable

s_lassen — Thu, 15 Jun 2023 07:50:14 GMT

I think you should drop the leading and trailing blanks, and look for word boundaries instead - beginning of string or end of string is also a word boundary:

pattern_id=prxparse('/\b(DONEPEZIL|GALANTAMINE|RIVASTIGMINE|MEMANTINE)\b/i');

Re: Adding a trailing space to a character variable

BayzidurRahman — Thu, 15 Jun 2023 21:14:21 GMT

That will pick the keyword by itself or with another keywords. For example, "DONEPEZIL" and "DONEPEZIL/OTHER". But i do not want the "DONEPEZIL/OTHER" to be picked up.

Re: Adding a trailing space to a character variable

Tom — Thu, 15 Jun 2023 23:47:16 GMT

@BayzidurRahman wrote:

That will pick the keyword by itself or with another keywords. For example, "DONEPEZIL" and "DONEPEZIL/OTHER". But i do not want the "DONEPEZIL/OTHER" to be picked up.

Do not add the spaces to the VARIABLE. Add them to the string you pass to the FUNCTION. Remember that means that the position that it found the start of the match is off by one because of the extra space.

pattern_id=prxparse('/ (DONEPEZIL|GALANTAMINE|RIVASTIGMINE|MEMANTINE) /i');

call prxnext(pattern_id, start, vlength(caps)+2 , ' '||caps||' ', position, length);
if (position>0) then cm_dementia=substr(caps, position-1, length);

Re: Adding a trailing space to a character variable

Patrick — Fri, 16 Jun 2023 04:39:14 GMT

It could also be done with a RegEx but in your case may-be just use the scan() function with a blank defined as the word delimiter.

data demo;
  infile datalines truncover;
  input str $100.;
  length cm_dementia $40;
  do _i=1 to countw(str,' ');
    cm_dementia=scan(str,_i,' ');
    if upcase(cm_dementia) in ('DONEPEZIL', 'GALANTAMINE', 'RIVASTIGMINE', 'MEMANTINE') then
    output;
  end;
datalines;
donepezil galantamine donepezil/other rivastigmine memantine
;
proc print data=demo;
run;