topic split name as single letter in SAS Programming

split name as single letter

BrahmanandaRao — Tue, 30 May 2023 04:54:05 GMT

data newdata (keep=word1-word7 name seqno);
retain seqno name;
array myvar (*)$ word1-word7;
set sashelp.class ;
by name notsorted;

	do seqno=1 to 7;
		do i= 1 to 7;
myvar(i)=substr(Name,i,1);
if last.name then output;

output; 
end;
end;
proc print noobs; run;

how to get complete split letters names output like below

seqno	name	word1	word2	word3	word4	word5	word6	word7
1	Alfred	A	l	f	r	e	d
2	Alice	A	l	i	c	e
3	Barbara	B	a	r	b	a	r	a

Re: split name as single letter

Kurt_Bremser — Tue, 30 May 2023 05:22:41 GMT

Why do you have two OUTPUT statements? Why do you use BY when there is only one observation per name anyway?

To create a sequential count variable, use RETAIN and a sum statement, you do not need a DO loop for this.

And use proper indentation when writing code, as all the people here are constantly showing you.

Hints: do not use an explicit OUTPUT, the DATA step will do this for you. Use one DO loop to scan through the name.

Re: split name as single letter

BrahmanandaRao — Tue, 30 May 2023 05:46:29 GMT

data newdata (keep=Letter_1-Letter_7 name);
	retain  name;
	array myvar (*)$ Letter_1-Letter_7;
	set sashelp.class;

	do i=1 to dim(myvar);
		myvar(i)=upcase(substr(name, i, 1));
	end;

proc print noobs;
run;

Thank you Kurt,

Re: split name as single letter

Kurt_Bremser — Tue, 30 May 2023 05:59:15 GMT

Study the documentation of the RETAIN Statement, and then decide if it is needed here, or if it does not serve any purpose at all.

Also look at the length of your newly created variables, you may want to change that, as you only store one character each.

Re: split name as single letter

yabwon — Tue, 30 May 2023 06:16:53 GMT

if I were you I would take a bit different approach:

Data;

data have;
  set sashelp.class(keep=name) end=E;
  output;
  if E then
  do;
    name='空手道';
    output;
    name='Żółć';
    output;
  end;
run;

Code:

proc sort data=have out=want;
by name;
run;

data want;
  set want;
  by name;
  do i=1 to KLENGTH(name);
    word = KSUBSTR(name,i,1);
    output;
  end;
run;
proc print;run;

proc transpose data=want out=want(drop=_name_) prefix=word;
  by name;
  var word;
run;

proc print;run;

Comments:

- Use klength() and ksubstr() to properly handle multi byte characters (which are quite common in names).

- Use data step to cut letters one by one and then use Proc Transpose, with that approach you won't have to assume maximum length of a name imagine you will have "Broomhilda" or "Małgorzata", or this man, which are much longer than 7 letters.

Bart

Re: split name as single letter

Patrick — Tue, 30 May 2023 12:01:51 GMT

Something like below should do.

proc sql noprint;
  select length into :len trimmed
  from dictionary.columns
  where libname='SASHELP' and memname='CLASS' and upcase(name)="NAME"
  ;
quit;

data newdata (keep=name letter_:);
  set sashelp.class;
  array letter_ (&len) $1;
  do _i=1 to length(name);
    letter_[_i]=substr(name,_i,1);
  end;
run;

proc print data=newdata noobs;
run;

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 07:30:38 GMT

Thank you Patrick for you solution how can get only maximum length names in the above class dataset

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 07:46:56 GMT

@BrahmanandaRao wrote:

Thank you Patrick for you solution how can get only maximum length names in the above class dataset

Please explain in more detail.

Do you want to display the maximun encountered length of a name at the end of the step, or do you want to only process the names having this maximum length, or even subset the dataset to these names?

See Maxim 42.

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 07:49:16 GMT

Hi kurt

i want get which name has maximum length those names only displays

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 07:53:34 GMT

In a first step, determine the maximum length (e.g. with PROC SQL SELECT INTO), then use this value in a WHERE.

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 08:29:58 GMT

proc sql ;
  select max(length(Name)) as maxlen into :len separated by ' '
  from newdata
  
  having name=max(name);
  
quit;

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 08:50:10 GMT

MAX of a character value gets the lexically "highest" (e.g. "Z" is higher than "A"), so I ask what you want to achieve with your HAVING clause?

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 09:33:19 GMT

data newdata (keep=Letter_1-Letter_7 name sex);
	retain  name;
	array myvar (*)$ Letter_1-Letter_7;
	set sashelp.class;

	do i=1 to dim(myvar);
		myvar(i)=upcase(substr(name, i, 1));
	end;

proc print noobs;
run;

/*Maximum length string in the newdataset */

PROC SQL;
   SELECT Name ,letter_1,letter_2,letter_3,letter_4,letter_5,letter_6,letter_7
   FROM NEWDATA
   WHERE LENGTH(Name) = (SELECT MAX(LENGTH(Name)) FROM NEWDATA);
QUIT;

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 09:45:19 GMT

Please READ my posts, and read them THOROUGHLY. I said you have to determine the maximum length in a FIRST step, so you can then use it in the WHERE condition of the DATA step that splits the name.

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 10:53:30 GMT

/* maximum length names output using datastep*/

data newdata (keep=Letter_1-Letter_7 name sex  );
	retain  name;
	array myvar (*)$ Letter_1-Letter_7;
	set sashelp.class;
    
	do i=1 to dim(myvar);
		myvar(i)=upcase(substr(name, i, 1));
		where max(length(name))=7  ;
	end;

proc print noobs;
run;
/*max and min names length using proc sql*/
PROC SQL;
   SELECT name,sex,letter_1,letter_2,letter_3,letter_4,letter_5,letter_6,letter_7,MAX(LENGTH(Name)) AS MaxLengthFemale
   FROM newdata
   WHERE Sex = 'F';
   
   SELECT name,sex,letter_1,letter_2,letter_3,letter_4,letter_5,letter_6,letter_7,MIN(LENGTH(Name)) AS MinLengthMale
   FROM newdata
   WHERE Sex = 'M';
QUIT;

1.How to get min and max names length output in datastep

Re: split name as single letter

PaigeMiller — Wed, 31 May 2023 12:58:31 GMT

Jumping in late here, and I realize this is a made up problem, but I cannot imagine what a "real" problem would be that requires these techniques. Could you please @BrahmanandaRao tell us what the "real" problem is?

We have spent a lot of time without a solution so far, and the translation to the "real" problem, whatever it is, may not be trivial. In addition, this strikes me as another example of the XY Problem, and knowing what the "real" problem is would point us in the right direction. In addition, any method that takes a long data set and turns it into a wide data set is a red-flag to me (while there are a few situations where that is necessary, most of the time it is a poor approach that takes you in the wrong direction, and misses easier ways to handle the data).

So to sum up, I think we have spent a lot of time on this, and that time would be better spent working on the "real" problem, not this made-up problem.

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 14:00:28 GMT

Use RETAINed variables (for max, start with 0, for min, start with 32767), use the MAX and MIN functions, and OUTPUT at the end (use the END= option in the SET statement).
Quite a simple problem, you can easily solve this on your own after 650+ posts here.

Re: split name as single letter

BrahmanandaRao — Wed, 31 May 2023 17:33:30 GMT

Hi Kurt,

I am not getting solution in datastep

Re: split name as single letter

Kurt_Bremser — Wed, 31 May 2023 18:47:20 GMT

You obviously didn't even give it a try, or you would have posted your code and log.