topic Re: Programming Help in SAS Programming

Extract folder search path from string

kumarsandip975 — Thu, 11 May 2023 15:04:10 GMT

data t1;
length v1 $ 100;
input v1 $;
datalines;
G:/Data/CXV/PGMS/CTS_Test/Scripts/ScannedFiles1.txt
D:/Data/ABC/PGMS/CTS_Test/Scripts/ScannedFiles2.txt
E:/Data/XYZ/PGMS/CTS_Test/Scripts/ScannedFiles3.txt
C:/Data/DEF/PGMS/CTS_Test/Scripts/ScannedFiles4.txt
F:/Data/JFK/PGMS/CTS_Test/Scripts/ScannedFiles5.txt
;
run;

I need to extract only folder, not file (which is last ). Can you please help.

G:/Data/CXV/PGMS/CTS_Test/Scripts
D:/Data/ABC/PGMS/CTS_Test/Scripts
E:/Data/XYZ/PGMS/CTS_Test/Scripts
C:/Data/DEF/PGMS/CTS_Test/Scripts
F:/Data/JFK/PGMS/CTS_Test/Scripts

Thanks in Adavance.

Re: Programming Help

MayurJadhav — Thu, 11 May 2023 12:53:07 GMT

You can use substr function in SAS to extract sub-string from a string. You can set the start and end position to fetch sub string from variable v1.

@kumarsandip975

Try this one:

data out; 
set t1;
v1_new = substr(v1,1, 33);
run;

Re: Programming Help

A_Kh — Thu, 11 May 2023 13:14:23 GMT

Addition to the above solution.

data want;
set t1;
v2= substr(v1, 1, length(v1) - length(scan(v1, -1, '/'))-1);
proc print; run;

This code works for dynamic path.

Finding folder name from string

PaigeMiller — Thu, 11 May 2023 13:59:06 GMT

data want;
    set t1;
    where=find(v1,'/',-100);
    folder_name=substr(v1,1,where-1);
    drop where;
run;

@kumarsandip975 please do not use meaningless subject lines like "Programming Help", because virtually every thread can be "Programming Help". Please, from now on, make the subject line a brief description of the problem.

Re: Extract folder search path from string

Ksharp — Fri, 12 May 2023 11:40:07 GMT

data t1;
length v1 $ 100;
input v1 $;
want=prxchange('s/\/[^\/]+$//',1,strip(v1));
datalines;
G:/Data/CXV/PGMS/CTS_Test/Scripts/ScannedFiles1.txt
D:/Data/ABC/PGMS/CTS_Test/Scripts/ScannedFiles2.txt
E:/Data/XYZ/PGMS/CTS_Test/Scripts/ScannedFiles3.txt
C:/Data/DEF/PGMS/CTS_Test/Scripts/ScannedFiles4.txt
F:/Data/JFK/PGMS/CTS_Test/Scripts/ScannedFiles5.txt
;
run;