topic Proc comparison with different data types. in SAS Programming

Proc comparison with different data types.

Akshaya_1397 — Tue, 09 May 2023 13:18:22 GMT

Hi All,
Can anyone please suggest me what to do if the data types is different in both the files while doing proc comparison.

Code:
Proc compare base=file1 compare=file2;
ID userid useritemid;
Run;

In the above example
File1 - userid as character
File2 - userid as numeric

File1-useritemid as character
File2-useritemid as numeric

Error message:the following 2 ID variables have inconsistent types in the base and comparison data sets;userid useritemid.

Can anyone suggest what to do in this case

Re: Proc comparison with different data types.

Astounding — Tue, 09 May 2023 14:09:20 GMT

As you have seen, the PROC step won't execute under these conditions. You would have to convert one or the other data set. However, you don't need to create a new data set. Instead, create a view and feed the view into PROC COMPARE. One possibility (converting from character to numeric in the first file):

data file1_numeric / view=file1_numeric;
   set file1;
   temp_id = input(userid, 8.);
   temp_item = input(useritemid, 8.);
   drop userid useritemid;
   rename temp_id = userid;
   rename temp_item = useritemid;
run;

Then run your PROC COMPARE with file1_numeric and file2.

Of course the best solution would be to user the same structure in both of your data sets originally. And the second best solution would be to permanently convert your current data sets so they use the same structure. But if you are looking for a third best solution, this would be a way to approach it.

You may run into other problems. For example, perhaps some of the IDs were made character because they couldn't be stored as numeric. Perhaps they contain letters. You would have to examine the log for cases where the INPUT function gives you a message about invalid data. When the INPUT function uses the 8. informat, it assumes that you have nothing longer than 8 digits. If you have longer values, using a longer length in the INPUT function.

Re: Proc comparison with different data types.

Kurt_Bremser — Tue, 09 May 2023 14:52:15 GMT

Go back to the process that created a userid as numeric. This process is faulty and needs to be fixed.

Re: Proc comparison with different data types.

Akshaya_1397 — Fri, 12 May 2023 11:09:33 GMT

Thankyou for the detailed explanation.
It worked for me thanks.