topic Re: RE label multiple variables in SAS Programming

RE label multiple variables

Emma2021 — Mon, 01 May 2023 23:56:27 GMT

I have multiple variables as var1, var2,…var78, num1,num2 etc.
They all have labels. I want to change the labels by adding 3 strings : for example, for all variables with start var then add VAR at the beginning of the labels if num1 etc all variables with start num then add NUM at the beginning of the all labels. How can I do that? Thank you.

Re: RE label multiple variables

Tom — Tue, 02 May 2023 02:45:20 GMT

If the number of variables is small (or more accurately the total length of all of the new labels is small) enough to fit into a macro variable just use an SQL query to generate the code needed.

proc sql noprint;
select catx('=',nliteral(name),quote(catx(' ',substr(name,1,3),label),"'"))
  into :labels separated by ' '
  where libname = 'WORK'
    and memname='HAVE'
    and upcase(substr(name,1,3)) in ('VAR','NUM')
    and label ne ' '
  ;
quit;
proc datasets nolist lib=work;
  modify have ;
    label &labels;
  run;
quit;

Re: RE label multiple variables

Emma2021 — Tue, 02 May 2023 10:38:08 GMT

If too long—can we stratify by var variables and num variables? How can do that? Thank you so much.

Re: RE label multiple variables

AhmedAl_Attar — Tue, 02 May 2023 11:06:06 GMT

Hi @Emma2021

One wat to get around the potential "too long" scenario would be writing the code into a separate file, and then running the newly created file 😉

Basically take @Tom original code and re-arrange it slightly

filename dyncode temp;

data _null_;
	length str $300;
	file dyncode lrecle=300;
	put 'proc datasets nolist lib=work;' ;
	put +3 'modify have ;' ;
	put +3 'label ';
	do until(eof);
		SET sashelp.vcolumn(where=(libname='WORK' and memname='HAVE' and upcase(substr(name,1,3)) in ('VAR','NUM') and label ne ' ')) 
			end=eof;
		str = catx('=',nliteral(name),quote(catx(' ',substr(name,1,3),label),"'"));
		put +6 str;
	end;	
	put +3 ';';
	put 'run; quit; ';
run;
%include dyncode;

The generated code should be a single Proc Datasets step.

Hope this help

Re: RE label multiple variables

yabwon — Tue, 02 May 2023 12:06:14 GMT

You already have a solution, but just for fun, an alternative one with proc transpose and call execute():

data have;
  retain var1 - var78 "abc" num1 - num20 0 A B C D E F G "xxx";
  ATTRIB
    var1 -- var78 label= "some label"
    num1 -- num20 label= "other lable"
    A -- G        label= 'different variables'
  ;
run;

proc transpose data=have(obs=0) out=temp;
  var var: num:;
run;
data _null_;
  call execute('
    proc datasets nolist lib=work;
      modify have ;
        label');
  do until(eof);
    set temp end=eof;
    call execute(cat(_NAME_,"='",substr(_NAME_,1,3)," ",_LABEL_,"'"));
  end;

  call execute(';run;quit;');
stop;
run;

Bart

Re: RE label multiple variables

Emma2021 — Tue, 02 May 2023 12:16:11 GMT

It gives an error that no from statement and no found name variable

Re: RE label multiple variables

AhmedAl_Attar — Tue, 02 May 2023 12:32:32 GMT

insert
FROM dictionary.columns
above
Where libname = 'WORK'