topic Re: PROC DATASETS "WARNING: No matching members in directory." in SAS Programming

PROC DATASETS "WARNING: No matching members in directory."

SASuserlot — Fri, 21 Apr 2023 15:54:05 GMT

I am cleaning the 'work' library before the start of the program by using the following code. However, I am getting the warning message in the log 'WARNING: No matching members in the directory.'

Can I avoid this or any alternatives where I can delete the existing datasets in the 'work' library before the start of the program? I thought of using it at the end ( but this will not help when the datasets are already there, and it may overwrite my datasets.)

Thank you.

dm 'log;clear;output;clear;odsresults ;clear';
proc datasets lib=work memtype=data kill;
quit;

Re: PROC DATASETS "WARNING: No matching members in directory."

AhmedAl_Attar — Fri, 21 Apr 2023 16:02:48 GMT

proc datasets lib=work memtype=data kill NOWARN;
quit;

Re: PROC DATASETS "WARNING: No matching members in directory."

SASuserlot — Fri, 21 Apr 2023 18:28:46 GMT

No luck 😥

Re: PROC DATASETS "WARNING: No matching members in directory."

AhmedAl_Attar — Fri, 21 Apr 2023 19:18:36 GMT

@SASuserlot

This should do it

data _null_;
	set sashelp.vtable(where=(libname='WORK' and MEMTYPE='DATA')) nobs=obs;
	if (obs > 0) then
	  rc = dosubl('proc datasets lib=work memtype=data kill NOLIST NOWARN;run;quit;');
run;

Re: PROC DATASETS "WARNING: No matching members in directory."

AhmedAl_Attar — Fri, 21 Apr 2023 19:23:26 GMT

This data step would only run the Proc Datasets step if there were data set(s) in the WORK library.
You can test it by adding a dummy data before the data _null_ step

Re: PROC DATASETS "WARNING: No matching members in directory."

SASuserlot — Fri, 21 Apr 2023 19:25:47 GMT

Thank you. It is working now.

Re: PROC DATASETS "WARNING: No matching members in directory."

Ksharp — Sat, 22 Apr 2023 11:46:18 GMT

Try option NODSNFERR .

options nodsnferr;
proc datasets lib=work memtype=data kill nolist nodetails;
quit;

Re: PROC DATASETS "WARNING: No matching members in directory."

SASuserlot — Wed, 26 Apr 2023 19:10:34 GMT

Thank you

Re: PROC DATASETS "WARNING: No matching members in directory."

Tom — Wed, 26 Apr 2023 19:20:18 GMT

Use NOLIST option not the NOWARN option.

Try this example:

data x; run;
proc datasets lib=work memtype=data nolist kill;
quit;
proc datasets lib=work memtype=data nolist kill;
quit;

1102  data x; run;

NOTE: The data set WORK.X has 1 observations and 0 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds


1103  proc datasets lib=work memtype=data nolist kill;
NOTE: Deleting WORK.X (memtype=DATA).
1104  quit;

NOTE: PROCEDURE DATASETS used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds


1105  proc datasets lib=work memtype=data nolist kill;
1106  quit;

NOTE: PROCEDURE DATASETS used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds