topic Re: Assign the same value by group of variables in SAS Programming

Assign the same value by group of variables

ramgouveia — Wed, 19 Apr 2023 10:40:15 GMT

I have this code

data have;
infile datalines dlm=',' dsd;
input ID $ var1 $ var2 $ var3 $;
datalines;
ID 00, ,Y,
ID 00, , ,
ID 00,Y, ,
ID 01,Y, ,Y
ID 01, , ,
;
data want;
do until (last.id);
update have(obs=0) have;
by ID;
end;
do until (last.id);
set have (keep=id);   by id;
output;
end;
run;

I got this code here:

https://communities.sas.com/t5/SAS-Programming/assign-the-same-value-by-group/td-p/717919

Instead of grouping by one variable I want to group by two or more variables. How can I adapt the code to this dataset?

data have2;
infile datalines dlm=',' dsd;
input ID_A $ ID_B $ var1 $ var2 $ var3 $;
datalines;
ID 00, ID 10, ,Y,
ID 00, ID 10, , ,
ID 00, ID 20,Y, ,
ID 00, ID 20, , ,
ID 01, ID 10,Y, ,Y
ID 01, ID 10, , ,
ID 01, ID 20, ,Y,
ID 01, ID 20, , ,
;

Re: Assign the same value by group of variables

PeterClemmensen — Wed, 19 Apr 2023 10:58:43 GMT

Try this

data have2;
infile datalines dlm=',' dsd;
input ID_A $ ID_B $ var1 $ var2 $ var3 $;
datalines;
ID 00, ID 10, ,Y,
ID 00, ID 10, , ,
ID 00, ID 20,Y, ,
ID 00, ID 20, , ,
ID 01, ID 10,Y, ,Y
ID 01, ID 10, , ,
ID 01, ID 20, ,Y,
ID 01, ID 20, , ,
;


data want;
   do until (last.ID_B);
      update have2(obs=0) have2;
      by ID_A ID_B;
   end;
   do until (last.ID_B);
      set have2 (keep=ID_A ID_B);  
      by ID_A ID_B;
      output;
   end;
run;

Re: Assign the same value by group of variables

ramgouveia — Wed, 19 Apr 2023 11:13:22 GMT

@PeterClemmensen

And if I want do do this only for var2 instead of var1, var2, and var3?

Re: Assign the same value by group of variables

PeterClemmensen — Thu, 20 Apr 2023 08:29:25 GMT

@ramgouveia Sorry for the late reply. Did you find your answer?

Re: Assign the same value by group of variables

ramgouveia — Thu, 20 Apr 2023 11:13:25 GMT

@PeterClemmensen

This one solved my problem.

Filling empty cells with other cells of the same column

Thank you anyway.