topic Re: Is there an equivalent to "IN" for macros? in SAS Programming

Is there an equivalent to "IN" for macros?

mariko5797 — Tue, 04 Apr 2023 13:32:08 GMT

My code is similar to below. I have a lot of different datasets and %if &dsn in (CMD DEM DV2) doesn't seem to work. Is there a different command that does the same thing?

%macro Counts(dsn, varlist);
data &dsn.1;
set an.&dsn_an;
%if &dsn= CMD|&dsn= DEM|&dsn= DV2 %then %do;
where protseg in ('A' 'B');
%end;
array vars{*} &varlist.;
num=0; den=0;
do i=1 to dim(vars);
if vars{i} in ("a" "d" "g" "j") then den = sum(den, 1); /*denominator*/
if vars{i} in ("j") then num = sum(num, 1); /*numerator*/
end;
run;
%mend;

Re: Is there an equivalent to "IN" for macros?

PaigeMiller — Tue, 04 Apr 2023 13:37:40 GMT

See the MINOPERATOR option and the MINDELIMITER option.

Re: Is there an equivalent to "IN" for macros?

Tom — Tue, 04 Apr 2023 15:10:09 GMT

If you want the macro processor to treat IN as an operator you need to tell it that with the MINOPERATOR option.

But if you are going to use IN as an operator inside a macro definition then it is best to set that option on %MACRO statement instead of depending on the whims of the user that is calling the macro.

%macro Counts(dsn, varlist) / minoperator mindelimter=' ';
data &dsn.1;
  set an.&dsn_an;
%if &dsn in CMD DEM DV2 %then %do;
  where protseg in ('A' 'B');
%end;
  array vars{*} &varlist.;
  num=0; den=0;
  do i=1 to dim(vars);
/*denominator*/
    if vars{i} in ("a" "d" "g" "j") then den = sum(den, 1);
/*numerator*/
    if vars{i} in ("j") then num = sum(num, 1); 
  end;
run;
%mend Counts;

PS Make it easier to read the code by placing comments about what the code is going to do BEFORE the code instead of afterwords.