topic Re: Open %IF / %ELSE to create part of a statement in SAS Programming

Open %IF / %ELSE to create part of a statement

Quentin — Fri, 24 Mar 2023 15:18:44 GMT

I don't use an open (i.e. outside of macro definition) %IF much.

Today I was playing with open %IF for a communities question, and hit a problem where it looks like open %ELSE can't be used to generate part of a statement. Feels like perhaps a bug? Unless it's documented that open %IF/%ELSE shouldn't be used to generate part of a SAS statement.

This step won't compile (9.4M7):

data want ;
 set 
   %if 0 %then %do ;
     sashelp.class
   %end ;
   %else %do ;
     sashelp.shoes
   %end ;
 ;
run ;

The error is:

480  data want ;
481   set
482     %if 0 %then %do ;
483       sashelp.class
484     %end ;
485     %else %do ;
486       sashelp.shoes
          -------------
          557
ERROR 557-185: Variable sashelp is not an object.

487     %end ;
ERROR: DATA STEP Component Object failure.  Aborted during the COMPILATION phase.
NOTE: The SAS System stopped processing this step because of errors.
488   ;
489  run ;

If I put the beginning of the SET statement in the %IF block it works. But there is another oddity. Below code works, even though there is no semicolon to end the SET statement:

data want ;
 %if 0 %then %do ;
   set sashelp.class
 %end ;
 %else %do ;
   set sashelp.shoes
 %end ;
run ;

and below code will error:

data want ;
 %if 0 %then %do ;
   set sashelp.class
 %end ;
 %else %do ;
   set sashelp.shoes
 %end ;
 sashelp.cars ;
run ;

Interestingly, the problem seems to be related to the code generated by the open %ELSE. If I change the first %IF to %IF 1, then all of the above examples give the results I would expect.

data want ;
 set 
   %if 1 %then %do ;
     sashelp.class
   %end ;
   %else %do ;
     sashelp.shoes
   %end ;
 ;
run ;


*errors because of missing semicolon for SET statement;
data want ;
 %if 1 %then %do ;
   set sashelp.class
 %end ;
 %else %do ;
   set sashelp.shoes
 %end ;
run ;

data want ;
 %if 1 %then %do ;
   set sashelp.class
 %end ;
 %else %do ;
   set sashelp.shoes
 %end ;
 sashelp.cars 
 ;
run ;

Re: Open %IF / %ELSE to create part of a statement

PaigeMiller — Fri, 24 Mar 2023 15:23:26 GMT

Your exact code inside a macro works, so yes, your example does feel like a bug to me.

%macro dothis;
data want ;
 set
   %if 0 %then %do ;
     sashelp.class
   %end ;
   %else %do ;
     sashelp.shoes
   %end ;
 ;
run ;
%mend;
%dothis

Re: Open %IF / %ELSE to create part of a statement

ErikLund_Jensen — Fri, 24 Mar 2023 15:47:06 GMT

Hi @Quentin

It works in Linux but not in Windows, so I think you are right in assuming it is a bug.

Re: Open %IF / %ELSE to create part of a statement

Quentin — Fri, 24 Mar 2023 15:49:09 GMT

Thanks, will submit it as a bug.

Re: Open %IF / %ELSE to create part of a statement

Tom — Fri, 24 Mar 2023 17:53:14 GMT

Support for open code %IF is very limited.

I would suggest using a macro variable so that you have complete statements inside the %DO/%END blocks.

663  %if 0 %then %do ;
664    %let dsn=sashelp.class;
665  %end ;
666  %else %do ;
667    %let dsn=sashelp.shoes;
668  %end ;
669  data want ;
670   set &dsn ;
671  run ;

NOTE: There were 395 observations read from the data set SASHELP.SHOES.
NOTE: The data set WORK.WANT has 395 observations and 7 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.01 seconds

Re: Open %IF / %ELSE to create part of a statement

Quentin — Fri, 24 Mar 2023 21:40:11 GMT

Heard back from Tech Support already. Macro legend Russ Tyndall explained this is a known bug, already documented:

https://support.sas.com/kb/65/310.html

Re: Open %IF / %ELSE to create part of a statement

Quentin — Mon, 27 Mar 2023 12:45:32 GMT

Russ updated me that the bug is fixed in 9.4M8.