topic Re: Cross Freq every var in a dataset in SAS Programming

Cross Freq every var in a dataset

SAShole — Mon, 14 Jul 2014 19:46:09 GMT

Hi SAS friends,

I have a much larger version of the following dataset and my task is to perform cross-frequency tables on every binary variable (e.g. Has_Income HasGender etc..). i'm looking to capture every combination but I consider HasGender*HasIncome the same as HasIncome*HasGender. Can you help me solve this one?

data Have;

input ID $2. HaveAge HaveGender HaveIncome;

cards;

1 0 0 0

2 1 1 1

3 0 1 0

4 1 1 0

5 1 1 1

6 1 1 0

7 1 0 1

8 1 0 0

9 1 0 1

run;

proc freq data = Have;

table HaveAge*HaveGender/out=want1;

table HaveAge*HaveIncome/out=want2;

table HaveGender*HaveIncome/out=want3;

run;

Re: Cross Freq every var in a dataset

data_null__ — Mon, 14 Jul 2014 19:52:49 GMT

WAYS!

data Have;
   input ID:$2. HaveAge HaveGender HaveIncome;
   cards; 
1 0 0 0
2 1 1 1
3 0 1 0
4 1 1 0
5 1 1 1
6 1 1 0
7 1 0 1
8 1 0 0
9 1 0 1
;;;;
   run; 
proc summary data=have chartype; 
   class have:;
   ways 2; 
   output out=twoway;
   run;

Re: Cross Freq every var in a dataset

KevinViel — Mon, 14 Jul 2014 20:32:24 GMT

As as statistician, I might warn against this for some purposes. Programmatically, you could do the following:

data one ;
array have_ ( 5 ) ( 5 * 1 ) ;
run ;

proc sql ;
create table name as
select name
from sashelp.vcolumn
where libname = "WORK"
and memname = "ONE"
;
quit ;

data _null_ ;
length tables_list $ 5000 ;
do i = 1 to &sqlobs. ;
    set name point = i ;
   do j = i + 1 to &sqlobs. ;
     want + 1 ;
     set name ( rename = ( name = name2 ))
                      point = j
                     ;
      tables_list = catx ( " "
                                  , tables_list
                                 , cat( "table "
                                        , strip( name )
                                        , "*"
                                       , strip( name2 )
                                       , "/out=want"
                                       , strip( put( want , 8. ))
                                       , ";"
                                      )
                                 ) ;
    end ;
end ;
call symput( "tables_list" , tables_list ) ;
stop ;
run ;

proc freq data = one ;
&tables_list. ;
run ;

Not sure how the formating (indenting) looks...

Of course, the only reason to take this approach in light of data_null_'s solution would be to learn about the various tools and data available. The CLASS statement above could be replaced with:

class _all_ ;

in certain circumstances.

HTH,

Kevin

Re: Cross Freq every var in a dataset

stat_sas — Mon, 14 Jul 2014 20:51:52 GMT

proc tabulate data=have out=want(drop=_type_ _page_ _table_);

class HaveAge HaveGender HaveIncome;

table HaveAge HaveGender HaveIncome,HaveAge HaveGender HaveIncome;

run;

Re: Cross Freq every var in a dataset

Reeza — Mon, 14 Jul 2014 21:08:08 GMT

Make sure to correct for multiple testing.

Re: Cross Freq every var in a dataset

Ksharp — Tue, 15 Jul 2014 14:28:22 GMT

data Have;

input ID $2. HaveAge HaveGender HaveIncome;

call sortn(HaveGender, HaveIncome);

cards;

1 0 0 0

2 1 1 1

3 0 1 0

4 1 1 0

5 1 1 1

6 1 1 0

7 1 0 1

8 1 0 0

9 1 0 1

run;

proc freq;

................

Xia Keshan