topic Re: Week Assignment to Dates in SAS Programming

Week Assignment to Dates

jnivi — Mon, 20 Mar 2023 23:28:18 GMT

Hi there,

I have a fairly large dataset (data=have) that spans a time period from February 21, 2021 to December 31, 2022. I was wondering if there is an automated function to assign a week number to each date in my dataset. I know SAS usually assigns week numbers by the start of the Calendar year, however I would like Week #1 to be 21FEB2021 to 27FEB2021, Week 2 to 28FEB2021 to 06MAR2021, and so forth. I have included a sample dataset that i would like below (data=want). Thank you once again for any help you might be able to offer!

OBS ID DATE WEEK

1 1001 22FEB2021 1

2 8997 05APR2021

3 5654 30SEP2022

4 3000 07MAR2022 3

5 1002 31OCT2021

6 7984 29FEB2021 2

Re: Week Assignment to Dates

Hao_Luo — Tue, 21 Mar 2023 01:15:33 GMT

"29FEB2021" may not be a valid date.

Re: Week Assignment to Dates

Hao_Luo — Tue, 21 Mar 2023 01:27:04 GMT

data have;
 input id$ date date9.;
 format date date9.;
 cards;
1001 22FEB2021
8997 05APR2021
5654 30SEP2022
3000 07MAR2022
1002 31OCT2021
7984 28FEB2021
;
run;

data want;
  set have;

  week=ceil((date-'21feb2021'd+1)/7);
run;

Re: Week Assignment to Dates

Patrick — Tue, 21 Mar 2023 01:47:05 GMT

Assuming you're after some sort of a study week number below should work.

data have;
  format date date9.;
  do date='21FEB2021'd to '31dec2022'd;
    output;
  end;
run;

data want;
  set have;
  study_week=intck('week','21FEB2021'd,date)+1;
run;

Re: Week Assignment to Dates

john_mccall — Tue, 21 Mar 2023 03:04:02 GMT

Consider this example using INTNX.

Data Original;
infile datalines ;
Input ID :4. Date :date9.;
format date date9.;
datalines;
1001 22FEB2021
8997 05APR2021
5654 30SEP2022
3000 07MAR2022
1002 31OCT2021
7984 28FEB2021
;
run;
Data Weeks;
Retain Date1 0;
set original ;
if _n_=1 then Date1='21FEB2021'd;
/* Use INTNX to count weeks between 21FEB2021 and dates in the table*/
Weeks=intck('week', date1,Date, 'continuous');
format date1 date9.;
run;