topic Re: PROC REPORT order=data within levels of grouping variable in SAS Programming

PROC REPORT order=data within levels of grouping variable

mtnbikerjoshua — Fri, 17 Mar 2023 21:22:53 GMT

Hi,

I am creating a report with a count of each value for several different parameters. All levels of the "value" variable need to appear in the same order as found in the data. Unfortunately, the levels for two of the parameters each include "Other", so PROC REPORT encounters "Other" from the first parameter before any of the levels of the second parameter and "Other" shows up first instead of last for the second parameter. Any ideas on the easiest way to fix this?

Example:

data test;
  input param $ value $;
  datalines;
param1 level1
param1 level2
param1 level3
param1 other
param2 level4
param2 level5
param2 level6
param2 other
;
run;

proc report data=test;
  columns param value n;
  define param / group;
  define value / group order=data;
run;

Have:

Want:

Re: PROC REPORT order=data within levels of grouping variable

ballardw — Fri, 17 Mar 2023 21:46:37 GMT

Add another variable to your data set that has the absolute order that you want.

Make that the column before the problem variable and define it as an Order variable and NOPRINT so that it does not appear in they output.

data test;
  input param $ value $ realorder;
  datalines;
param1 level1 1
param1 level2 2
param1 level3 3
param1 other  4
param2 level4 5
param2 level5 6
param2 level6 7
param2 other  8
;
run;

proc report data=test;
  columns  param realorder value n;
  define param / group;
  define realorder / order noprint ;
  define value / group ;
run;

If your data is in the display order you need then you can add the "realorder" variable in a data step as;

data need;
   set have;
   realorder=_n_;
run;

Re: PROC REPORT order=data within levels of grouping variable

FreelanceReinh — Fri, 17 Mar 2023 22:29:28 GMT

Hi @mtnbikerjoshua,

Another option might be to create a preliminary report dataset (called REP below) using BY-group processing and then create the actual report from that.

ods select none;
proc report data=test out=rep(drop=_:);
by param; /* add NOTSORTED option if necessary */
column value n;
define value / group order=data;
run;
ods select all;

proc report data=rep;
define param / order order=data;
define n / display;
run;

Re: PROC REPORT order=data within levels of grouping variable

Ksharp — Sat, 18 Mar 2023 09:16:59 GMT

data test;
  input param $ value $;
  datalines;
param1 level1
param1 level2
param1 level3
param1 other
param2 level4
param2 level5
param2 level6
param2 other
;
run;

proc report data=test;
  columns param value n;
  define param / group;
  define value / group order=internal;
run;

/*or could try order=format , but you need create a format firstly*/

Re: PROC REPORT order=data within levels of grouping variable

mtnbikerjoshua — Mon, 20 Mar 2023 14:59:06 GMT

This does, in fact, work for the test data I provided, but in the real data there are some categories that are not in alphabetical order, so I need to stick with order=data.

Re: PROC REPORT order=data within levels of grouping variable

mtnbikerjoshua — Mon, 20 Mar 2023 15:23:53 GMT

This solution ended up working nicely for me after a bit of tweaking. My real report has an across variable, so I had to make sure the data was grouped by the param and value variables, then create my realorder variable like this:

data test2;
  set test;
  by param value notsorted;
  if _n_ = 1 then realorder = 0;
  if first.value then realorder + 1;
run;

I also had to make sure to place the realorder variable immediately before the value variable in the report and make it a group variable, so that it wouldn't mess up my grouping.