topic If results in dataset then write message to results window in SAS Programming

If results in dataset then write message to results window

JC411911 — Thu, 23 Feb 2023 19:42:03 GMT

Hello,

I have a fairly simple program that I need to create that will display text depending on two conditions of a dataset. The program runs but the text is not displayed in the results window but rather in the log. How can I write the below to get the text to show once the program is run without having to look in the log?

data _NULL_;
set me.prim_data nobs=numobs;
if numobs>0 and payment_channel = 'CREDIT' then PUT 'NEED CREDIT FILE AND LETTER';
RUN;

Re: If results in dataset then write message to results window

Tom — Thu, 23 Feb 2023 19:49:12 GMT

Just add a FILE statement to tell the data step where you want it to go.

For example use FILE PRINT to write to whatever ODS destinations you have open.

Note you cannot test for NUMOBS=0 after the SET statement because if it is zero then the SET statement is the last statement that will execute because it will read past the end of the input.

data _NULL_;
  file print;
  if numobs=0 then put 'FILE IS EMPTY';
  set me.prim_data nobs=numobs;
  if  payment_channel = 'CREDIT' then PUT 'NEED CREDIT FILE AND LETTER';
run;

Do you really want to write that message for every observation that has payment_channel equal to CREDIT?

How many observations are in that dataset? You might want to stop at the first one.

data _NULL_;
  file print;
  if numobs=0 then put 'FILE IS EMPTY';
  set me.prim_data nobs=numobs;
  if  payment_channel = 'CREDIT' then do;
    PUT 'NEED CREDIT FILE AND LETTER';
    stop;
  end;
run;

Re: If results in dataset then write message to results window

JC411911 — Thu, 23 Feb 2023 19:51:20 GMT

Ah that worked. This may be nitpicky but is there a way to just get the text to list one time regardless if the statement is true and there are many observations? In that result I see "NEED CREDIT FILE AND LETTER" multiple times since there are hundreds of obrservations that meet the criteria.

Re: If results in dataset then write message to results window

ballardw — Thu, 23 Feb 2023 20:02:00 GMT

data _NULL_; file print; if numobs=0 then put 'FILE IS EMPTY'; set me.prim_data nobs=numobs; retain flag 0; if payment_channel = 'CREDIT' and flag=0 then do; PUT 'NEED CREDIT FILE AND LETTER'; flag=1; stop; end; run;

The retain keeps a variable's value across iteration of the data step. So initialize to 0, in example, and then the first time you execute the Put change the value to something else.

Re: If results in dataset then write message to results window

Tom — Thu, 23 Feb 2023 20:09:32 GMT

Just STOP.

Even easier if you use a WHERE statement.

data _null_:
  file print;
  if 0=numobs then put 'None found';
  set mydata nobs=numobs;
  where (xx='CHECK');
  put 'Found some.';
  stop;
run;

Re: If results in dataset then write message to results window

Reeza — Thu, 23 Feb 2023 20:12:06 GMT

Use CALL EXECUTE + PROC ODSTEXT

data _NULL_;
set sashelp.class nobs=numobs;
if numobs>0  then call execute("proc odstext;
   p 'NEED CREDIT FILE AND LETTER'  / style=[color=red fontsize=25pt];
run;");
RUN;

@JC411911 wrote:

Hello,

I have a fairly simple program that I need to create that will display text depending on two conditions of a dataset. The program runs but the text is not displayed in the results window but rather in the log. How can I write the below to get the text to show once the program is run without having to look in the log?
data _NULL_;
set me.prim_data nobs=numobs;
if numobs>0 and payment_channel = 'CREDIT' then PUT 'NEED CREDIT FILE AND LETTER';
RUN;