topic Get string between parenthesis only in SAS Programming

Get string between parenthesis only

jmmedina252 — Tue, 21 Feb 2023 14:46:43 GMT

Hi, I'm trying to get a string between parenthesis when there are characters before and after the parenthesis. The string looks like this: GGT (U/L) 1 - 5

I want the output to be this: U/L

Re: Get string between parenthesis only

PaigeMiller — Tue, 21 Feb 2023 14:58:39 GMT

Assuming there is only one left parenthesis and one right parenthesis (is that a good assumption?)

data want;
    set have;
    left=find(variablename,'(');
    right=find(variablename,')');
    desired_string=substr(variablename,left+1,right-left-1);
run;

Re: Get string between parenthesis only

Astounding — Tue, 21 Feb 2023 15:15:25 GMT

As long as parentheses are not the first character, you can use:

inside = scan(variable, 2, ')(');

This selects the second set of characters within the string, using parentheses as delimiters.

Re: Get string between parenthesis only

ballardw — Tue, 21 Feb 2023 16:41:11 GMT

And easy enough to test if the ( is the first character:

data example;
   input string $10.;
datalines;
GGT (U/L)  
(start) of
;

data want;
   set example;
   if string =:'(' then want= scan(string,1,'()');
   else want=scan(string,2,'()');
run;

If you have not seen the =: that is basically a "begins with". So if the first character is ( then the first bit is grabbed, otherwise the second.

Re: Get string between parenthesis only

Ksharp — Wed, 22 Feb 2023 11:50:17 GMT

/*Assuming there is only one parenthesis*/
data example;
   input string $40.;
datalines;
GGT (U/L)    1 - 5
(start) of
;
data want;
 set example;
 pid=prxparse('/\(.*?\)/');
 call prxsubstr(pid,string,p,l);
 if p then want=compress(substr(string,p,l),'()');
 drop p l pid;
run;