topic Re: How to create baseline_data in a easy way in SAS Programming

How to create baseline_data in a easy way

nwang5 — Tue, 14 Feb 2023 00:14:09 GMT

Is there any easy to express the sentences below?

if lle9^=. then age_baseline=R9AGEY_B;
else if lle10^=. then age_baseline=R10AGEY_B;
else if lle11^=. then age_baseline=R11AGEY_B;
else if lle12^=. then age_baseline=R12AGEY_B;
else if lle13^=. then age_baseline=R13AGEY_B;
else if lle14^=. then age_baseline=R14AGEY_B;

Re: How to create baseline_data in a easy way

ballardw — Tue, 14 Feb 2023 06:06:58 GMT

Define "easy".

I can do it in slightly shorter code but whether it is easier or not is questionable.

Untested code as no values provided

array ab (*) R9AGEY_B R10AGEY_B R11AGEY_B R12AGEY_B R13AGEY_B R14AGEY_B;
baseline = ab [whichn(1,lle9^=. ,lle10^=.,lle11^=.,lle12^=.,lle13^=.,lle14^=.)];

The Whichn, and character version Whichc, returns the position of the first expression or value following the first that matches that value. So we find the first result of 1 from the comparisons. SAS will return 1 for true so evaluating lle9 ^=. results in 1 when not missing.

The ARRAY allows addressing a value of the array using it's position number. This is where the bit about middle of the variable comes in. You will learn that with SAS it often a much better idea to name the variable R_agey_b9, or similar. Then the list could have been R_agey_b9 -R_agey_b14.

For the above to work you have to make sure that the order of the comparisons matches that of the variables in the array.

Or a two array solution

array ab (*) R9AGEY_B R10AGEY_B R11AGEY_B R12AGEY_B R13AGEY_B R14AGEY_B;
array l (*) lle9 - lle14;
do i=1 to dim(l);
   if l[i] ne . then do;
      baseline=ab[i];
      leave;
   end;
run;

Re: How to create baseline_data in a easy way

andreas_lds — Tue, 14 Feb 2023 06:43:14 GMT

This "solution" demonstrates how to avoid loops:

options missing = '#';

data want;
   set have;

   length value $ 10 all $ 200 p baseline 8;

   array one lle9-lle14;
   array two R9AGEY_B R10AGEY_B R11AGEY_B R12AGEY_B R13AGEY_B R14AGEY_B;

   value = put(coalesce(of one[*]), best.);
   all = catx(' ', of one[*]);
   p = findw(all, strip(value), ' ', 'e');

   baseline = two[p];

   *drop value all p;
run;

options missing = '.';

While coalesce still sees "missing", catx keeps missing values and displays them as #, so findw returns the number of the "word" matching the first non-missing value, which is the value of array two becoming the value of baseline.

In real-life i would use the second suggestion posted by @ballardw