topic Convert string date to date value in SAS Programming

Convert string date to date value

cm3 — Mon, 23 Jan 2023 19:13:10 GMT

I have a variable Enrollment_month - type character, length 8 with value ex:FEB2022. I want to convert this into date format as 20220201. Please help

Re: Convert string date to date value

Kurt_Bremser — Mon, 23 Jan 2023 19:17:43 GMT

Since your notation fits most of the DATE9 informat, conversion is easy:

data want;
set have (rename=(enrollment_month=_em));
format enrollment_month yymmddn8.;
enrollment_month = input(cats("01",_em),date9.);
drop _em;
run;

PS I changed your subject line. "Hi" is not descriptive and only makes you look silly.

Re: Hi

SASKiwi — Mon, 23 Jan 2023 19:22:01 GMT

data Want;
  Enrollment_month = 'FEB2022';
  Enrollment_date = input('01' !! Enrollment_month, date9.);
  format Enrollment_date yymmddn8.;
  put _all_;
run;

Re: Convert string date to date value

cm3 — Mon, 23 Jan 2023 19:40:55 GMT

your solution worked , thank you.
Thanks for updating the title, it was bit confusing in mobile and I missed it

Re: Hi

cm3 — Mon, 23 Jan 2023 19:43:53 GMT

Also I was wondering how would we convert if enrollment_month is type date with same value?? Pls confirm

Re: Hi

Kurt_Bremser — Mon, 23 Jan 2023 20:15:41 GMT

If it is already a SAS date value, you only need to change the assigned format, e.g. with PROC DATASETS for the dataset, or with a FORMAT statement (or FORMAT= option in PROC SQL) wherever needed.

Re: Hi

SASKiwi — Mon, 23 Jan 2023 20:25:21 GMT

"If enrollment_month is type date with same value" - A numeric variable can't contain the same value as "FEB2022" as that is character data. The closest you can get is this, where you define it as a date based on 01 Feb 2022:

data Want;
  Enrollment_month = '01FEB2022'd;
  Enrollment_date = Enrollment_month; 
  format Enrollment_month date9. Enrollment_date yymmddn8.;
  put _all_;
run;

Re: Hi

Kurt_Bremser — Mon, 23 Jan 2023 21:29:10 GMT

PS there is no type "date" in SAS. SAS has only two types of variables, character and numeric.

Dates are stored in numeric variables, as counts of days with 1960-01-01 as day zero, and with a proper format assigned to make the raw value human-readable.

Re: Convert string date to date value

Ksharp — Tue, 24 Jan 2023 05:24:43 GMT

Also could try MONYY. informat.

data Want;
Enrollment_month = 'FEB2022';
Enrollment_date = input(Enrollment_month, monyy9.);
format Enrollment_date yymmddn8.;
put _all_;
run;