HTML Output: Data interpreted as HTML control characters

Patrick — Sat, 21 Jan 2023 07:48:09 GMT

Hi all,

Using SAS EG while populating and then printing a control table with some test data I've encountered a case where the data messes-up the output (sample below).

Do you know of any way to avoid such a result without having to encode characters in the source data so they become "html safe"?

data work.sample;
  infile datalines4 truncover dlm='|' dsd;
  input
    rule_type :$30.
    rule_desc :$100.
    ;
  datalines4;
Not Null|Raise issue if value is missing
In a List|Raise issue if value NOT found in a list
Not In a List|Raise issue if value found in a list
In Value Range|Raise issue if value NOT within boundaries
Not In Value Range|Raise issue if value within boundaries
Lookup Exist|<table for hash> <keyvar(s) hash> <keyvar(s) table if different names>
Not Lookup Exist|<table for hash> <keyvar(s) hash> <keyvar(s) table if different names>
Unique Key|<space separated list of variables that make up the unique key>
Custom Function|Any SAS expression that return True or False. Example: <var 1> = <var 2>
;;;;

proc print data=work.sample;
run;

Thanks,

Patrick

Re: HTML Output: Data interpreted as HTML control characters

Ksharp — Sat, 21 Jan 2023 14:41:09 GMT

Patrick,

Try this one.

data work.sample;
  infile datalines4 truncover dlm='|' dsd;
  input
    rule_type :$30.
    rule_desc :$100.
    ;
  datalines4;
Not Null|Raise issue if value is missing
In a List|Raise issue if value NOT found in a list
Not In a List|Raise issue if value found in a list
In Value Range|Raise issue if value NOT within boundaries
Not In Value Range|Raise issue if value within boundaries
Lookup Exist|<table for hash> <keyvar(s) hash> <keyvar(s) table if different names>
Not Lookup Exist|<table for hash> <keyvar(s) hash> <keyvar(s) table if different names>
Unique Key|<space separated list of variables that make up the unique key>
Custom Function|Any SAS expression that return True or False. Example: <var 1> = <var 2>
;;;;

proc report data=work.sample nowd style(column)={PROTECTSPECIALCHARS=yes};
run;

topic Re: HTML Output: Data interpreted as HTML control characters in SAS Programming

HTML Output: Data interpreted as HTML control characters

Re: HTML Output: Data interpreted as HTML control characters