topic Re: Day Count in SAS Programming

Day Count

Eugenio211 — Mon, 04 Apr 2022 14:18:54 GMT

Hello! Hope all is well!

I've run the code below and did not get the correct result for 'Saturday'. For the period of Jan 1, 2022 to March 31, 2022 I only get 12 instead of 13. Does any one know what if there is an error with my code? thanks.

>%let startdate = 1Jan2022;
%let enddate = 31Mar2022;

data Weekdays;
Sunday = intck('weekday234567W',"&startdate"d,"&enddate"d);
Monday = intck('weekday134567W',"&startdate"d,"&enddate"d);
Tuesday = intck('weekday124567W',"&startdate"d,"&enddate"d);
Wednesday = intck('weekday123567W',"&startdate"d,"&enddate"d);
Thursday = intck('weekday123467W',"&startdate"d,"&enddate"d);
Friday = intck('weekday123457W',"&startdate"d,"&enddate"d);
Saturday = intck('weekday123456W',"&startdate"d,"&enddate"d);
put _all_;
run;

this is the data I got:

Sunday	Monday	Tuesday	Wednesday	Thursday	Friday	Saturday
13	13	13	13	13	12	12

Re: Day Count

Kurt_Bremser — Mon, 04 Apr 2022 14:36:55 GMT

Just count how many Saturdays are between the startdate and enddate. This year, there are 12.

Re: Day Count

AMSAS — Mon, 04 Apr 2022 16:31:01 GMT

As @Kurt_Bremser points out the INTCK function counts between the dates, and Jan 1st was a Saturday in 2022 and hence is not counted

Returns the number of interval boundaries of a given kind that lie between two dates, times, or datetime values.

Re: Day Count

FreelanceReinh — Mon, 04 Apr 2022 17:06:15 GMT

Hello @Eugenio211,

Wouldn't it be easier to use shifted week intervals?

data Weekdays;
Sunday    = intck('week.1',"&startdate"d-1,"&enddate"d);
Monday    = intck('week.2',"&startdate"d-1,"&enddate"d);
Tuesday   = intck('week.3',"&startdate"d-1,"&enddate"d);
Wednesday = intck('week.4',"&startdate"d-1,"&enddate"d);
Thursday  = intck('week.5',"&startdate"d-1,"&enddate"d);
Friday    = intck('week.6',"&startdate"d-1,"&enddate"d);
Saturday  = intck('week.7',"&startdate"d-1,"&enddate"d);
put (_all_)(=);
run;

With the inserted "-1" the interval boundary before the start date is taken into account.

Re: Day Count

SAShole — Tue, 10 Jan 2023 17:12:19 GMT

Hi @FreelanceReinh, I like this solution.

Can you say a little more about the 'Week.1' - 'Week.7' arguments. I guess Week.1 is equivalent to weekday234567W. I can't find either in the documentation -- just curious how you know to use these.

Thank you,

Re: Day Count

PaigeMiller — Tue, 10 Jan 2023 17:28:45 GMT

https://documentation.sas.com/doc/en/pgmmvacdc/9.4/leforinforref/n0pxq4af0hx60nn1i1x3xn41mc3c.htm#n0zn1re74n6pfvn170g9us41coho

Re: Day Count

FreelanceReinh — Tue, 10 Jan 2023 18:31:41 GMT

Hi @SAShole,

Here's another documentation link: Incrementing Dates and Times by Using Multipliers and By Shifting Intervals. The subsequent section "Commonly Used Time Intervals" includes the example

WEEK.2

Weekly intervals starting on Mondays

@SAShole wrote:

I guess Week.1 is equivalent to weekday234567W.

Yes, I think this is true, but it's also equivalent to the plain Week interval without a shift index. The Weekday interval can be a bit tricky to understand at times, so the Week.i intervals seemed more intuitive to me for Eugenio211's task.