topic Re: Bar Chart And Chi-Squared Test in SAS Programming

Bar Chart And Chi-Squared Test

wespol — Mon, 12 Dec 2022 01:39:36 GMT

Hello,

I have a CSV file similar to this one:

;Red;Blue;Green;Yellow;Black
Group 1;472;124;577;242;367
Group 2;272;97;715;252;255
Group 3;246;233;121;144;209

And I would like to get a bar chart such as the following, then do a chi-squared test:

I can't find a solution by browsing the documentation; could someone please help me?

Thanks.

Re: Bar Chart And Chi-Squared Test

Ksharp — Mon, 12 Dec 2022 03:30:57 GMT

data have;
infile cards truncover dlm=';';
input group :$40. Red Blue Green Yellow Black;
cards4;
Group 1;472;124;577;242;367
Group 2;272;97;715;252;255
Group 3;246;233;121;144;209
;;;;

proc transpose data=have out=want;
by group;
var _numeric_;
run;

proc sgplot data=want;
vbar _name_/group=group response=col1  groupdisplay=cluster;
xaxis label=' ';
yaxis label=' ';
run;


proc freq data=want;
table _name_*group/chisq ;
weight col1;
run;

Re: Bar Chart And Chi-Squared Test

wespol — Mon, 12 Dec 2022 14:15:21 GMT

Thank you for your feedback.
Is there any way to do it immediately from the CSV file?

Re: Bar Chart And Chi-Squared Test

ballardw — Mon, 12 Dec 2022 16:26:15 GMT

@wespol wrote:
Thank you for your feedback.
Is there any way to do it immediately from the CSV file?

SAS basically works with SAS data sets. So read an external file, such as CSV, into a data set and then do analysis or other actions with that data set.

Re: Bar Chart And Chi-Squared Test

Ksharp — Tue, 13 Dec 2022 02:33:24 GMT

Sure .It is easy to read CSV into SAS .

proc import datafile='c:\temp\have.csv' out=have dbms=csv replace;
delimiter=';';
guessingrows=max;
run;