topic Re: proc means - variable label on statistics in SAS Programming

proc means - variable label on statistics

xxformat_com — Thu, 24 Nov 2022 12:43:04 GMT

Hi,

The attrib/label statement will only remove the labels of the input variable but not of the statistics computed with proc means.

Is there any option which could be used to avoid an extra data step/proc datasets?

In the example, the N Obs label is first added on the computed nobs variable, and so on.

ods exclude all;
ods output summary=test;

proc means data=sashelp.class ;
    class sex;

    var height;
    *attrib _all_ label=' ';
run;
ods exclude none;

proc print data=test label noobs;
run;

proc datasets lib=work nolist;
   modify test;
   attrib _all_ label=' ';
   run;
quit;

proc print data=test label noobs;
run;

Re: proc means - variable label on statistics

PeterClemmensen — Thu, 24 Nov 2022 12:40:04 GMT

What is the real objective here? To create a report with no labels or to create a data set with statistics with no labels?

Re: proc means - variable label on statistics

xxformat_com — Thu, 24 Nov 2022 12:43:47 GMT

statistics with no label.

Re: proc means - variable label on statistics

PeterClemmensen — Thu, 24 Nov 2022 13:04:49 GMT

In a data set or a report?

Re: proc means - variable label on statistics

PaigeMiller — Thu, 24 Nov 2022 15:18:28 GMT

@xxformat_com wrote:
statistics with no label.

Please be kind and explain why you want this. Should you achieve this "statistics with no label", what would you do with the resulting statistics with no label, that requires no label and would not work properly if there is a label?

I believe that the default label for variables is the variable name.

Re: proc means - variable label on statistics

Tom — Thu, 24 Nov 2022 18:04:49 GMT

I really don't understand what the issue is. If you don't want to print the labels then don't print the labels.

proc print data=test noobs;
run;

Or just skip using ODS output and instead use the OUTPUT statement to generate a dataset.

That dataset does not add labels.

You can also make a wider dataset.

proc means data=sashelp.class nolabels;
  class sex;    var height;
  output out=stats;
  output out=stats_wide n= min= max= mean= std= / autoname ; 
run;

Re: proc means - variable label on statistics

xxformat_com — Thu, 24 Nov 2022 17:07:59 GMT

no variable label in the dataset as given in the example.

Re: proc means - variable label on statistics

Kurt_Bremser — Thu, 24 Nov 2022 17:37:32 GMT

And what will you do with the dataset?

Re: proc means - variable label on statistics

PaigeMiller — Thu, 24 Nov 2022 17:43:37 GMT

Well, @xxformat_com , you have been asked several times for explanation about what you will do with this "statistic with no label" once you have it. Please provide the answer.

Re: proc means - variable label on statistics

Reeza — Thu, 24 Nov 2022 18:29:04 GMT

SAS adds variable labels by default. To remove them you can modify the template (which would affect every time you run PROC MEANS), remove them after in the saved dataset using a variety of methods (proc dataset, data step), or ensure the following procedures use variable names not labels. Or explicitly calculate your statistics in a more manual fashion such as proc sql or tabulate where you can control the labels.

Re: proc means - variable label on statistics

Ksharp — Fri, 25 Nov 2022 01:34:31 GMT

Just add this option
options nolabel;
at the top of your code.

Re: proc means - variable label on statistics

xxformat_com — Wed, 30 Nov 2022 18:59:38 GMT

@Ksharp Actually no. Here is an example showing that using the global option is not helping:

options nolabel;
ods exclude all;
ods output summary=test;

proc means data=sashelp.class ;
    class sex;    var height;
    attrib _all_ label=' ';
run;
ods exclude none;
options label;

proc sql;
    select name, format, label
    from dictionary.columns
    where upcase(libname)='WORK' and
          upcase(memname)='TEST';
quit;

proc print data=test label noobs;
run;

Re: proc means - variable label on statistics

xxformat_com — Wed, 30 Nov 2022 19:02:39 GMT

@tomy Actually I was not expecting any difference between ods output statement and the output statement.

I'm really surprise that both label and format are added to output datasets by default without any possibility to avoid them upfront.

I don't see as beneficially to have to go back to old syntax because of that or add additional steps.

Re: proc means - variable label on statistics

Tom — Wed, 30 Nov 2022 19:10:30 GMT

It is normally much better to use the datasets that a procedure can generate. They are designed to used as data. The stuff you can capture via ODS is stuff that is designed to be a REPORT.

Re: proc means - variable label on statistics

ballardw — Wed, 30 Nov 2022 22:06:20 GMT

@xxformat_com wrote:

@Ksharp Actually no. Here is an example showing that using the global option is not helping:

options nolabel;
ods exclude all;
ods output summary=test;

proc means data=sashelp.class ;
    class sex;    var height;
    attrib _all_ label=' ';
run;
ods exclude none;
options label;

proc sql;
    select name, format, label
    from dictionary.columns
    where upcase(libname)='WORK' and
          upcase(memname)='TEST';
quit;

proc print data=test label noobs;
run;

That actually doesn't "prove" what you may think. Since you are using ODS OUTPUT to create a data set then the rules imposed by that process, ods output, apply which is providing a column heading which makes a lot of sense with the multiple variables that are supported in column with ODS output.

Consider

options nolabel;
ods select all;
proc summary data=sashelp.class nway ;
    class sex;    
    var height;
    output out=test2 min= max= std= /autoname;
   
run;

options label;
proc sql;
    select name, format, label
    from dictionary.columns
    where upcase(libname)='WORK' and
          upcase(memname)='TEST2';
quit;
proc print data=test2 label;
run;

The output data set here does not have any "label". SAS will use the variable name as a label when not provided or the option NOLABEL is set.

Proc summary calculates all the same statistics as means and creates data sets. In fact for many years Means did not create sets, just print output, and Summary created sets but no print output. The two have been merged and have some slightly different default behaviors to be consistent will older output. The output statement has the AUTOLABEL option to force adding the statistic text to the existing variable label or variable name if not present.

Re: proc means - variable label on statistics

Ksharp — Thu, 01 Dec 2022 07:31:58 GMT

Since you have already add options nolable;

there is no need to add LABEL option in PROC PRINT.

proc print data=test label noobs;
run;
------->
proc print data=test  noobs;
run;

Re: proc means - variable label on statistics

Ksharp — Thu, 01 Dec 2022 07:41:40 GMT

options nolabel ;

is just suppress the label ,not remove it .

If you want remove it .

I am afraid you need some other code :

ods output summary=test;
proc means data=sashelp.class ;
    class sex;    var height;
run;
ods exclude none;



proc datasets library=work nolist nodetails;
modify test;
attrib _all_ label=' ';
quit;




proc sql;
    select name, format, label
    from dictionary.columns
    where upcase(libname)='WORK' and
          upcase(memname)='TEST';
quit;

proc print data=test label noobs;
run;