topic Re: Output subsequent values when variable occurs the first time a dataset in SAS Programming

Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 12:58:37 GMT

Dear all, if I have a data that looks like this

data have;
infile datalines;
input id var1 var2 var3 var4 $3.;
datalines;
1 4  3 2 5
2 2  4 5 6
3 4  6 7 8
4 8  4 2 5
5 6  1 0 10
6 10 1 4 5
7 4 5 6 4
8 1  4 6 4
9 5  5 9 10
10 4 9 4 4
;
run;

I want each time the value of var1=4 occurs for the first time, all values of subsequent variables to be outputted . e.g. for id=1, the output will be 3, 2, 5

id=2, will be 5 and 6 etc.

Any help?

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 13:02:21 GMT

Outputted how? Can you post the form of your desired result?

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 13:26:32 GMT

data want should look like this

id	var1	var2	var3	var4
1	4	3	2	5
2		4	5	6
3	4	6	7	8
4		4	2	5
6			4	5
7	4	5	6	4
8		4	6	4
10	4	9	4	4

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 13:29:41 GMT

Ok. Is var4 character and the other vars numeric intentionally?

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 13:32:16 GMT

sorry, var1-var4 are characters only the id is numeric

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 13:38:22 GMT

Ok. Try this

data have;
infile datalines;
input id (var1 - var4)($);
datalines;
1 4  3 2 5
2 2  4 5 6
3 4  6 7 8
4 8  4 2 5
5 6  1 0 10
6 10 1 4 5
7 4 5 6 4
8 1  4 6 4
9 5  5 9 10
10 4 9 4 4
;
run;

data want(drop = flag);
   set have;
   array v $ var:;
   if '4' in v;

   do over v;
      if v = '4' then flag = 1;
      if flag = . then v = '';
   end;
run;

Result:

id var1 var2 var3 var4
1  4    3    2    5
2       4    5    6
3  4    6    7    8
4       4    2    5
6            4    5
7  4    5    6    4
8       4    6    4
10 4    9    4    4

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 13:42:59 GMT

Thanks this was very fast, will this also work if var were to be numeric?

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 13:49:48 GMT

If they were all numeric, then yes, but of course, you would have to change '4' to 4 🙂

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 13:52:44 GMT

yes, I tried that and it also worked, thanks

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 13:54:33 GMT

Anytime.

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 14:09:57 GMT

@PeterClemmensen sorry I still need to ask this question for feature use. In case I need for this output not only the subsequent values but also the previous values how can I add this in the code?

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 14:10:08 GMT

Meaning you want to blank all values besides the first one that is =4 / '4' ?

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 14:23:36 GMT

meaning that I want in the output also the values of the blanks to show.

and secondly, probably I wouldn't like to display the first occurence of 4 in the results

it should then look like this:

so that I can later concatenate easily;

id	var1	var2	var3	var4
1		3	2	5
2	2		5	6
3		6	7	8
4	8		2	5
6	10	1		5
7		5	6	4
8	1		6	4
10		9	4	4

Re: Output subsequent values when variable occurs the first time a dataset

PeterClemmensen — Thu, 24 Nov 2022 14:28:31 GMT

This blanks simply all the '4' values?

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Thu, 24 Nov 2022 14:36:00 GMT

sorry, I didn't understand your question. I was thinking of blanking all the first '4' values not all the '4' values and outputting also the preceeding values

Re: Output subsequent values when variable occurs the first time a dataset

Anita_n — Sat, 26 Nov 2022 14:46:33 GMT

This is my final solution

data want(drop=i);
set have;

array v(*) _character_ ;
if '4' in v;

do i=1 to dim(v);
  if v{i}='4' then do;
   v{i}= '';
   leave;
end;
end;

run;