topic Re: output XPT filenames in lowercase in SAS Programming

output XPT filenames in lowercase

bharath86 — Tue, 22 Nov 2022 05:17:59 GMT

Hi,

This macro outputs XPT files with file names in 'uppercase'. Can we change this and give the output filenames in 'lowercase'?

You can use any sas dataset from your directory. Please change the path (input path and output path) or you can use sashelp library too.

%macro xpt;
libname raw_sets " input Path ";
proc contents data=raw_sets._all_ out=datasets  noprint;
run;
proc sql noprint;
select distinct(MEMNAME),count(distinct(MEMNAME)) into:alldata1-,:datan
from datasets;
quit;

/*%put &alldata1,&datan;*/

%do i=1 %to  &datan;

libname raw_xpt xport "output path\&&alldata&i...xpt";

proc copy in=raw_sets out=Raw_xpt memtype=data;
select &&alldata&i.;
run;
%end;
%mend xpt;
%xpt;

Thank you

Re: output XPT filenames in lowercase

Tom — Tue, 22 Nov 2022 05:53:32 GMT

Why not just use the LOWCASE() function?

Fix the SQL step.

proc sql noprint;
  select distinct lowcase(MEMNAME)
    into :alldata1-
  from datasets
  ;
%let datan=&sqlobs;
quit;

You could also get rid of the macro (or at least the macro logic and macro variables).

libname raw_sets " input Path ";
proc contents data=raw_sets._all_ out=datasets  noprint;
run;
data _null_;
  set datasets;
  by memname;
  if first.memname;
  call execute(catx(' '
   , 'libname raw_xpt xport'
   , quote(cats('output path/', lowcase(memname), '.xpt'),"'")
   , ';'
   , 'proc copy in=raw_sets out=raw_xpt mt=data;'
   , 'select', memname, ';'
   , 'run;'
  ));
run;

Re: output XPT filenames in lowercase

Ksharp — Tue, 22 Nov 2022 07:39:59 GMT

libname raw_xpt xport "output path\&&alldata&i...xpt";
----->
libname raw_xpt xport "output path\ %lowcase( &&alldata&i...xpt ) ";

Re: output XPT filenames in lowercase

bharath86 — Tue, 22 Nov 2022 07:55:12 GMT

Simple and Elegant.