topic Re: Inflation cost analysis in SAS Programming

Inflation cost analysis

CathyVI — Mon, 24 Oct 2022 21:01:36 GMT

Hi,

I am doing inflation cost analysis which am new to using sas. I will like to produce an output for all cost variables but I only have output for total.

Please any help with how the code can generate the outputs e.g. inf_cost_hosp, inf_cost_ed,

inf_cost_rx and inf_cost_out and not only the inf_cost_total?

Here is the code:

%macro cost(var1);
data a2007_2011;
set b2007_2011;
if obsyear='2006' then inf_cost_&var1.=cost_&var1.*1.10;
else if obsyear='2007' then inf_cost_&var1.=cost_&var1.*1.08;
else if obsyear='2008' then inf_cost_&var1.=cost_&var1.*1.04;
else if obsyear='2009' then inf_cost_&var1.=cost_&var1.*1.04;
else if obsyear='2010' then inf_cost_&var1.=cost_&var1.*1.01;
else inf_cost_&var1.=cost_&var1.;
run;
%mend cost;
%cost(hosp);
%cost(ed);
%cost(out);
%cost(rx);
%cost(total);

Re: Inflation cost analysis

PaigeMiller — Mon, 24 Oct 2022 22:12:58 GMT

Using a macro seems unnecessary and inefficient here. I have also written the code assuming year is a numeric variable, which it should be. You will have to somehow create a list of variables in the ARRAY statement, if their names all begin with COST_ then it's pretty simple.

data want;
     set b2007_2011;
     if obsyear=2006 then factor=1.1;
     else if obsyear=2007 then factor=1.08;
     else if /* you type the rest */ ;
     array cost cost_:;
     do i=1 to dim(cost);
         cost(i)=factor*cost(i);
     end;
run;

Re: Inflation cost analysis

Reeza — Mon, 24 Oct 2022 22:47:33 GMT

data want;
     set b2007_2011;
     array _factor[2006:2010] _temporary_ (1.10, 1.08, 1.04, 1.04, 1.01)
     _year = input(year, 8.);
     array cost cost_:;
     do i=1 to dim(cost);
        if  2006<=year<=2010 then factor=_factor(year);
        else factor=1;
         cost(i)=factor*cost(i);
     end;
run;

Adding the factors into an array makes it easier as well.

Re: Inflation cost analysis

Reeza — Mon, 24 Oct 2022 22:49:51 GMT

And how to make your code actually work as is. You were always starting from the base data set, overwriting any previous changes. To have the changes stick, you need to use the same data set.

%macro cost(var1);
data b2007_2011;
set b2007_2011;
if obsyear='2006' then inf_cost_&var1.=cost_&var1.*1.10;
else if obsyear='2007' then inf_cost_&var1.=cost_&var1.*1.08;
else if obsyear='2008' then inf_cost_&var1.=cost_&var1.*1.04;
else if obsyear='2009' then inf_cost_&var1.=cost_&var1.*1.04;
else if obsyear='2010' then inf_cost_&var1.=cost_&var1.*1.01;
else inf_cost_&var1.=cost_&var1.;
run;
%mend cost;

data b2007_2011;
set a2007_2011;
run;


%cost(hosp);
%cost(ed);
%cost(out);
%cost(rx);
%cost(total);