topic Re: Display SAS column name vertically with constant height and width in SAS Programming

Display SAS column name vertically with constant height and width

abraham1 — Tue, 18 Oct 2022 09:30:17 GMT

Hi,

I am getting error while running the below code in log file.

Unrecognized option: ROTATE_HEADERS
Unrecognized option: HEIGHT

I want to change the column header from horizontal to vertical format. Also all the columns should contain constant height of 10 and width of 7.

Can you please help

data test;
  input pid age gender race event2 $;
  label
    pid = 'Patient ID'
    age = 'Patient age'
    gender='Sex'
    race = 'Race'
    event2='Event 2'
  ;
cards;
101 21 1 1 fever
102 21 2 1 fever
103 31 1 1 fever
104 43 2 1 fever
;
ods tagsets.excelxp file='D:/outputs/test.xls'   style=normal
      options( rotate_headers="45"
               height="60");
proc print data=test ; run;
ods tagsets.excelxp close;

Re: Display SAS column name vertically with constant height and width

Ksharp — Tue, 18 Oct 2022 12:06:45 GMT

https://support.sas.com/rnd/base/ods/odsmarkup/msoffice2k/index.html

Re: Display SAS column name vertically with constant height and width

ballardw — Tue, 18 Oct 2022 16:47:14 GMT

@abraham1 wrote:

Hi,

I am getting error while running the below code in log file.

Unrecognized option: ROTATE_HEADERS
Unrecognized option: HEIGHT

I want to change the column header from horizontal to vertical format. Also all the columns should contain constant height of 10 and width of 7.

Height of 10 what units? MM, CM, Feet, furlongs?

Your requirement may have issues with the amount of text you attempt to place in a given height/width combination.

You may want define more of what you expect for "vertical format" headers.

You might not be aware of the Proc Print option Heading= that has one form of vertical headings.

As an example run (regardless of destination)

proc print data=test heading=vertical ; run;

Re: Display SAS column name vertically with constant height and width

abraham1 — Wed, 19 Oct 2022 01:41:48 GMT

I have just added sample data for reporting. I need to export the output to excel file with ods tagset excelxp option with column header to be displayed in vertical format.

Re: Display SAS column name vertically with constant height and width

Tom — Wed, 19 Oct 2022 04:40:14 GMT

Why would you want to use EXCELXP tagset instead of using the more recent EXCEL ods destination?

And if you are going to use that method why are you naming the file with .xls extension instead of .xml? It is going to be an XML file.

I suspect you want to add a style to the VAR statement of your PROC PRINT to tell EXCEL to rotate the headers.

Here is a line from an old report of mine from years ago when EXCELXP was actually kind of current technology.

  var &vlist
   /style={tagattr="format:###,###,###"}
    style(header)={tagattr='rotate:90 format:text'}
  ;

Re: Display SAS column name vertically with constant height and width

Ksharp — Wed, 19 Oct 2022 11:34:44 GMT

data test;
  input pid age gender race event2 $;
  label
    pid = 'Patient ID'
    age = 'Patient age'
    gender='Sex'
    race = 'Race'
    event2='Event 2'
  ;
cards;
101 21 1 1 fever
102 21 2 1 fever
103 31 1 1 fever
104 43 2 1 fever
;
ods tagsets.excelxp file='c:\temp\test.xls'   style=normal 
options( Row_Heights='200,20,20,20,20,20,20' Default_Column_Width='10')
;
proc report data=test nowd style(header)={tagattr='rotate:90 ' }; 
run;
ods tagsets.excelxp close;